06-1350/Class Notes for Tuesday October 24
| ||||||||||||||||||||||||||||||||||||||||||||||||||||||
What Cyclic Permutations Can't See
Believe or not, but the following questions are directly related to class material - specifically, to the determination of "The Envelope of The Alexander Polynomial".
Let [math]\displaystyle{ S_n }[/math] denote the permutation group on [math]\displaystyle{ n }[/math] letters and let [math]\displaystyle{ {\mathbb Q}S_n }[/math] denote its group ring. Let [math]\displaystyle{ c:{\mathbb Q}S_n\to{\mathbb Q} }[/math] be the linear functional defined via its definition on generators by [math]\displaystyle{ c(\sigma)=1 }[/math] if the permutation [math]\displaystyle{ \sigma }[/math] is cyclic, and [math]\displaystyle{ c(\sigma)=0 }[/math] otherwise. Turn [math]\displaystyle{ c }[/math] into a (symmetric!) bilinear form (also called [math]\displaystyle{ c }[/math]) on [math]\displaystyle{ {\mathbb Q}\otimes{\mathbb Q} }[/math] by setting [math]\displaystyle{ c(\tau,\sigma):=c(\tau^{-1}\sigma) }[/math].
Question 1. Determine the kernel [math]\displaystyle{ \ker c }[/math] of the bilinear form [math]\displaystyle{ c }[/math]. (Recall that the kernel of a bilinear form [math]\displaystyle{ \gamma }[/math] is [math]\displaystyle{ \{w:\forall v,\ \gamma(v,w)=0\} }[/math].
Question 2. For [math]\displaystyle{ n=4 }[/math], I know by a lengthy computation (see below) that [math]\displaystyle{ H }[/math] is in [math]\displaystyle{ \ker c }[/math], where
| [math]\displaystyle{ H = [(12),[(13),(14)]]-(14)-(23)+(13)+(24) }[/math] |
| [math]\displaystyle{ \ \ = [2134,[3214,4231]]-4231-1324+3214+1432 }[/math] |
| [math]\displaystyle{ \ \ = 2341-2413-3142+4123-4231-1324+3214+1432 }[/math] |
(here [math]\displaystyle{ (jk) }[/math] denotes the transposition of [math]\displaystyle{ j }[/math] and [math]\displaystyle{ k }[/math], [math]\displaystyle{ k_1k_2k_3k_4 }[/math] denotes the permutation for which [math]\displaystyle{ i\mapsto k_i }[/math], and the bracket is taken in the additive sense: [math]\displaystyle{ [\tau,\sigma]:=\tau\sigma-\sigma\tau) }[/math]. Do you have quicker explanation?
Question 3. By another lengthy computation for [math]\displaystyle{ n=4 }[/math], I also know that [math]\displaystyle{ Y_4\in\ker c }[/math], where
Do you have quicker explanation?
Question 4. I suspect that in some sense, though I'm not sure in which, [math]\displaystyle{ H }[/math] and [math]\displaystyle{ Y_4 }[/math] generate the whole kernel or at least some easily definable special part of the kernel of [math]\displaystyle{ c }[/math] for all [math]\displaystyle{ n }[/math]. Can you make sense of that?
The Lengthy Computations
The lengthy computation for [math]\displaystyle{ H }[/math] (and likewise for [math]\displaystyle{ Y_4 }[/math]) involves multiplying 24 "test permutations" against a linear combination of 8 permutations and counting cycles in the resulting 192 permutations. Here's a Mathematica session that does that:
In[1]:=
|
S[n_] := (P @@@ Permutations[Range[n]]);
c[p_P] := If[
Length[p] == Length[NestWhileList[p[[#]] &, p[[1]], # > 1 &]],
1, 0
];
c[x_] := x /. p_P :> c[p];
Unprotect[NonCommutativeMultiply];
p1_P ** p2_P := p1 /. Thread[Rule[Range[Length[p2]], List @@ p2]];
p1_ ** (p2_ + p3_) := p1 ** p2 + p1 ** p3;
(p1_ + p2_) ** p3_ := p1 ** p3 + p2 ** p3;
p1_ ** (c_*p2_P) := c p1 ** p2;
(c_*p1_P) ** p2_ := c p1 ** p2;
b[a_, b_] := a ** b - b ** a;
|
In[2]:=
|
H = b[P[2, 1, 3, 4], b[P[3, 2, 1, 4], P[4, 2, 3, 1]]]
- P[1, 3, 2, 4] + P[1, 4, 3, 2] + P[3, 2, 1, 4] - P[4, 2, 3, 1]
|
Out[2]=
|
-P[1, 3, 2, 4] + P[1, 4, 3, 2] + P[2, 3, 4, 1] - P[2, 4, 1, 3] -
P[3, 1, 4, 2] + P[3, 2, 1, 4] + P[4, 1, 2, 3] - P[4, 2, 3, 1]
|
In[3]:=
|
c[# ** H] & /@ S[4]
|
Out[3]=
|
{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0}
|
In[4]:=
|
Y4 = b[P[2, 1, 3, 4], P[1, 3, 2, 4]] - b[P[1, 3, 2, 4], P[1, 2, 4, 3]] +
b[P[1, 2, 4, 3], P[4, 2, 3, 1]] - b[P[4, 2, 3, 1], P[2, 1, 3, 4]]
|
Out[4]=
|
P[1, 3, 4, 2] - P[1, 4, 2, 3] - P[2, 3, 1, 4] + P[2, 4, 3, 1] +
P[3, 1, 2, 4] - P[3, 2, 4, 1] - P[4, 1, 3, 2] + P[4, 2, 1, 3]
|
In[5]:=
|
c[# ** Y4] & /@ S[4]
|
Out[5]=
|
{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0}
|
