Pensieve header: $\mathcal A$-calculus and the Hodge star. Continues Alpha.nb.

𝒜-Calculus

WP[Wedge[u___],Wedge[v___]]:=Signature[{u,v}]*Wedge@@Sort[{u,v}];
WP[0,_]=WP[_,0]=0;
WP[A_,B_]:=Expand[Distribute[A ** B] /. (a_. * u_Wedge) ** (b_. * v_Wedge):>a b WP[u,v]];

WP[Wedge[]+Wedge[a]-2b⋀a, Wedge[]-3Wedge[b]+7c⋀d]

WExp[A_]:=Module[{s=Wedge[],t=Wedge[],k=0},
While[t=!=0,s+=(t=Expand[WP[t,A]/(++k)])]; s]

WExp[a⋀b+c⋀d+e⋀f]

(Subscript[c, x_,y_])[w_Wedge]:=Module[{i,j},
{i}=FirstPosition[w,x,{0}]; {j}=FirstPosition[w,y,{0}];
(Piecewise[{{w, (i==0)∧(j==0)}, {(((-1))^(i+j+If[i>j,0,1]))Delete[w,{{i},{j}}], (i>0)∧(j>0)}}])
];
(Subscript[c, x_,y_])[ℰ_]:=ℰ/.w_Wedge:>(Subscript[c, x,y])[w]

WExp[a⋀b+2c⋀d]
(Subscript[c, d,c])@WExp[a⋀b+2c⋀d]

𝒜[(Subscript[X, i_,j_,k_,l_])[S_,T_]]:=𝒜[{l,i},{j,k},\[LeftAssociation](Subscript[ξ, i])->S,(Subscript[x, j])->T,(Subscript[x, k])->S,(Subscript[ξ, l])->T\[RightAssociation],Expand[(T^(-1/2))WExp[Expand[{(Subscript[ξ, l]),(Subscript[ξ, i])}.(({{1, 1-T}, {0, T}})).{(Subscript[x, j]),(Subscript[x, k])}]/.(Subscript[ξ, a_])(Subscript[x, b_]):>(Subscript[ξ, a])⋀(Subscript[x, b])]]];
𝒜[(Subscript[X, i_,j_,k_,l_])]:=𝒜[(Subscript[X, i,j,k,l])[(Subscript[τ, i]),(Subscript[τ, l])]];

𝒜[(Subscript[(OverBar[X]), i_,j_,k_,l_])[S_,T_]]:=𝒜[{i,j},{k,l},\[LeftAssociation](Subscript[ξ, i])->S,(Subscript[ξ, j])->T,(Subscript[x, k])->S,(Subscript[x, l])->T\[RightAssociation],Expand[(T^(1/2))WExp[Expand[{(Subscript[ξ, i]),(Subscript[ξ, j])}.(({{(T^(-1)), 0}, {1-(T^(-1)), 1}})).{(Subscript[x, k]),(Subscript[x, l])}]/.(Subscript[ξ, a_])(Subscript[x, b_]):>(Subscript[ξ, a])⋀(Subscript[x, b])]]];
𝒜[(Subscript[(OverBar[X]), i_,j_,k_,l_])]:=𝒜[(Subscript[(OverBar[X]), i,j,k,l])[(Subscript[τ, i]),(Subscript[τ, j])]];

𝒜[(Subscript[P, i_,j_])[T_]]:=𝒜[{i},{j},\[LeftAssociation](Subscript[ξ, i])->T,(Subscript[x, j])->T\[RightAssociation],WExp[(Subscript[ξ, i])⋀(Subscript[x, j])]];
𝒜[(Subscript[P, i_,j_])]:=𝒜[(Subscript[P, i,j])[(Subscript[τ, i])]]

𝒜[(Subscript[X, 1,2,3,4])[u,v]]

Linearity:

𝒜/:α_×𝒜[is_,os_,cs_,w_]:=𝒜[is,os,cs,Expand[α w]]
𝒜/:𝒜[is1_,os1_,cs1_,w1_]+𝒜[is2_,os2_,cs2_,w2_]/;(Sort@is1==Sort@is2)∧(Sort@os1==Sort@os2)∧(Sort@Normal@cs1==Sort@Normal@cs2):=𝒜[is1,os1,cs1,w1+w2]

Deciding if two $\calA$’s are equal:

𝒜/:𝒜[is1_,os1_,_,w1_]≡𝒜[is2_,os2_,_,w2_]:=TrueQ[(Sort@is1===Sort@is2)∧(Sort@os1===Sort@os2)∧PowerExpand[w1==w2]]

Disjoint unions:

𝒜/:𝒜[is1_,os1_,cs1_,w1_]𝒜[is2_,os2_,cs2_,w2_]:=𝒜[is1⋃is2,os1⋃os2,Join[cs1,cs2],WP[w1,w2]]

Short[𝒜[(Subscript[X, 2,4,3,1])[S,T]]𝒜[(Subscript[(OverBar[X]), 3,4,6,5])],5]

(Subscript[c, h_,t_])@𝒜[is_,os_,cs_,w_]:=𝒜[
DeleteCases[is,t],DeleteCases[os,h],KeyDrop[cs,{(Subscript[x, h]),(Subscript[ξ, t])}],(Subscript[c, (Subscript[x, h]),(Subscript[ξ, t])])[w]
] /. If[MatchQ[cs[(Subscript[ξ, t])],(Subscript[τ, _])], cs[(Subscript[ξ, t])]->cs[(Subscript[x, h])],cs[(Subscript[x, h])]-> cs[(Subscript[ξ, t])]];

(Subscript[c, 4,4])[𝒜[(Subscript[X, 2,4,3,1])[S,T]]𝒜[(Subscript[(OverBar[X]), 3,4,6,5])]]

c@𝒜[is_,os_,cs_,w_]:=Fold[(Subscript[c, #2,#2])[#1]&,𝒜[is,os,cs,w],is⋂os]
𝒜[{A_𝒜}]:=c[A];
𝒜[{A1_𝒜,As__𝒜}]:=Module[{A2},
A2=First@MaximalBy[{As},Length[A1[[1]]⋂#[[2]]]+Length[A1[[2]]⋂#[[1]]]&];
𝒜[Join[{c[A1 A2]}, DeleteCases[{As},A2]]] ]
𝒜[𝒪s_List]:=𝒜[𝒜/@𝒪s]

c[𝒜[(Subscript[X, 2,4,3,1])[S,T]]𝒜[(Subscript[(OverBar[X]), 3,4,6,5])]]

𝒜@{𝒜[(Subscript[X, 2,4,3,1])[S,T]],𝒜[(Subscript[(OverBar[X]), 3,4,6,5])]}

Skein Relations

𝒜@{(Subscript[(OverBar[X]), 4,1,6,3])[v,u],(Subscript[(OverBar[X]), 3,2,5,4])}

Reidemeister 2

{𝒜@{(Subscript[X, 2,4,3,1])[S,T],(Subscript[(OverBar[X]), 3,4,6,5])}≡𝒜@{(Subscript[P, 1,5])[T],(Subscript[P, 2,6])[S]}, 𝒜@{(Subscript[(OverBar[X]), 3,1,2,4])[S,T],(Subscript[X, 6,5,3,4])}≡𝒜@{(Subscript[P, 1,5])[T],(Subscript[P, 6,2])[S]}}

Reidemeister 3

𝒜@{(Subscript[X, 2,5,4,1])[(Subscript[T, 2]),(Subscript[T, 1])],(Subscript[X, 3,7,6,5])[(Subscript[T, 3]),(Subscript[T, 1])],(Subscript[X, 6,9,8,4])}≡𝒜@{(Subscript[X, 3,5,4,2])[(Subscript[T, 3]),(Subscript[T, 2])],(Subscript[X, 4,6,8,1])[(Subscript[T, 3]),(Subscript[T, 1])],(Subscript[X, 5,7,9,6])}

Reidemeister 1

{𝒜@{(Subscript[X, 3,3,2,1])}≡(Subscript[τ, 1]^(-1/2))𝒜@{(Subscript[P, 1,2])}, 𝒜@{(Subscript[X, 1,2,3,3])}≡(Subscript[τ, 1]^(1/2))𝒜@{(Subscript[P, 1,2])}, 𝒜@{(Subscript[(OverBar[X]), 1,3,3,2])}≡(Subscript[τ, 1]^(-1/2))𝒜@{(Subscript[P, 1,2])}, 𝒜@{(Subscript[(OverBar[X]), 3,1,2,3])}≡(Subscript[τ, 1]^(1/2))𝒜@{(Subscript[P, 1,2])}}

The Relation with the Multivariable Alexander Polynomial

MVA=(u^(-1/2))(v^(-1/2))(w^(-1/2))(u-1) (v-1) (w-1);

A={(Subscript[(OverBar[X]), 1,12,2,13])[u,v],(Subscript[(OverBar[X]), 13,2,6,3]),(Subscript[X, 8,4,9,3]),(Subscript[X, 4,10,5,9]),(Subscript[X, 6,17,7,16])[v,w],
(Subscript[X, 15,8,16,7]),(Subscript[(OverBar[X]), 14,10,15,11]),(Subscript[(OverBar[X]), 11,17,12,14])}//𝒜//Last//Factor

A==(u^(-1/2))(u-1)(u^0)(v^(-1/2))(w^(1/2))MVA(Wedge[]-(Subscript[x, 5])⋀(Subscript[ξ, 1]))

Overcrossings Commute but Undercrossings don’t

{𝒜@{(Subscript[X, 2,7,5,1]),(Subscript[X, 3,4,6,7])}≡𝒜@{(Subscript[X, 3,7,6,1]),(Subscript[X, 2,4,5,7])}, 𝒜@{(Subscript[(OverBar[X]), 1,2,7,5]),(Subscript[(OverBar[X]), 7,3,4,6])}≡𝒜@{(Subscript[(OverBar[X]), 1,3,7,6]),(Subscript[(OverBar[X]), 7,2,4,5])}}

The Conway Relation

𝒜@{(Subscript[X, 2,3,4,1])[T,T]} - 𝒜@{(Subscript[(OverBar[X]), 1,2,3,4])[T,T]}≡((T^(-1/2))-(T^(1/2)))𝒜@{(Subscript[P, 1,4])[T],(Subscript[P, 2,3])[T]}

Conway’s Second Set of Identities

{𝒜@{(Subscript[X, 2,4,3,1])[v,u],(Subscript[X, 4,6,5,3])} + 𝒜@{(Subscript[(OverBar[X]), 1,2,4,3])[u,v],(Subscript[(OverBar[X]), 3,4,6,5])}≡((u^(1/2))(v^(1/2))+(u^(-1/2))(v^(-1/2)))𝒜@{(Subscript[P, 1,5])[u],(Subscript[P, 2,6])[v]}, 
𝒜@{(Subscript[(OverBar[X]), 4,1,6,3])[v,u],(Subscript[(OverBar[X]), 3,2,5,4])} + 𝒜@{(Subscript[X, 1,6,3,4])[u,v],(Subscript[X, 2,5,4,3])}≡((u^(1/2))(v^(-1/2))+(u^(-1/2))(v^(1/2)))𝒜@{(Subscript[P, 1,5])[u],(Subscript[P, 2,6])[v]}}

{𝒜@{(Subscript[X, 2,3,4,1])} + 𝒜@{(Subscript[(OverBar[X]), 2,1,4,3])}≡((Subscript[τ, 1]^(1/2))+(Subscript[τ, 1]^(-1/2)))𝒜@{(Subscript[P, 1,3]),(Subscript[P, 2,4])}, 𝒜@{(Subscript[(OverBar[X]), 1,2,3,4])} + 𝒜@{(Subscript[X, 1,4,3,2])}≡((Subscript[τ, 2]^(1/2))+(Subscript[τ, 2]^(-1/2)))𝒜@{(Subscript[P, 1,3]),(Subscript[P, 2,4])}}

Conway’s Third Identity and Virtual Version (Archibald)

𝒜@{(Subscript[X, 6,4,9,1]),(Subscript[(OverBar[X]), 4,5,7,8]),(Subscript[(OverBar[X]), 2,3,5,6])} + 𝒜@{(Subscript[X, 2,4,5,1]),(Subscript[(OverBar[X]), 4,3,7,6]),(Subscript[X, 6,8,9,5])}≡𝒜@{(Subscript[(OverBar[X]), 1,6,4,9]),(Subscript[X, 5,7,8,4]),(Subscript[X, 3,5,6,2])} + 𝒜@{(Subscript[(OverBar[X]), 1,2,4,5]),(Subscript[X, 3,7,6,4]),(Subscript[(OverBar[X]), 5,6,8,9])}

𝒜@{(Subscript[X, 3,7,6,1]),(Subscript[(OverBar[X]), 7,2,4,5])} + 𝒜@{(Subscript[X, 2,4,7,1]),(Subscript[X, 3,5,6,7])}≡𝒜@{(Subscript[X, 3,7,6,2]),(Subscript[X, 7,4,5,1])} + 𝒜@{(Subscript[(OverBar[X]), 1,2,7,5]),(Subscript[X, 3,4,6,7])}

Jun Murakami’s Fifth Axiom and Virtual Versions (Archibald)

𝒜@{(Subscript[X, 1,4,2,5])[T,S],(Subscript[X, 4,3,5,2])} ≡(((Sqrt[S])(1-T))/(Sqrt[T]))𝒜@{(Subscript[P, 1,3])[T]}

𝒜@{(Subscript[X, 3,2,3,1])[S,T]} ≡((T^(-1/2))-(T^(1/2)))𝒜@{(Subscript[P, 1,2])[T]}

𝒜@{(Subscript[X, 1,3,2,3])}

Jun Murakami’s Third Axiom

(Subscript[𝒜, 2112])=𝒜@{(Subscript[X, 3,8,7,2]),(Subscript[X, 7,10,9,1]),(Subscript[X, 10,11,4,9]),(Subscript[X, 8,6,5,11])};
(Subscript[𝒜, 1221])=𝒜@{(Subscript[X, 2,8,7,1]),(Subscript[X, 3,10,9,8]),(Subscript[X, 10,6,11,9]),(Subscript[X, 11,5,4,7])};
(Subscript[𝒜, 2211])=𝒜@{(Subscript[X, 3,8,7,2]),(Subscript[X, 8,6,9,7]),(Subscript[X, 9,11,10,1]),(Subscript[X, 11,5,4,10])};
(Subscript[𝒜, 1122])=𝒜@{(Subscript[X, 2,8,7,1]),(Subscript[X, 8,9,4,7]),(Subscript[X, 3,11,10,9]),(Subscript[X, 11,6,5,10])};
(Subscript[𝒜, 11])=𝒜@{(Subscript[X, 2,8,7,1]),(Subscript[X, 8,5,4,7]),(Subscript[P, 3,6])};  (Subscript[𝒜, 22])=𝒜@{(Subscript[X, 3,8,7,2]),(Subscript[X, 8,6,5,7]),(Subscript[P, 1,4])};
(Subscript[𝒜, ∅])=𝒜@{(Subscript[P, 1,4]),(Subscript[P, 2,5]),(Subscript[P, 3,6])};
(SubPlus[g])[z_]:=(z^(1/2))+(z^(-1/2)); (SubMinus[g])[z_]:=(z^(1/2))-(z^(-1/2));
(SubPlus[g])[(Subscript[τ, 1])](SubMinus[g])[(Subscript[τ, 2])](Subscript[𝒜, 2112])-(SubMinus[g])[(Subscript[τ, 2])](SubPlus[g])[(Subscript[τ, 3])](Subscript[𝒜, 1221])-(SubMinus[g])[(Subscript[τ, 3])/(Subscript[τ, 1])]((Subscript[𝒜, 2211])+(Subscript[𝒜, 1122]))+(SubMinus[g])[(Subscript[τ, 2])(Subscript[τ, 3])/(Subscript[τ, 1])](SubPlus[g])[(Subscript[τ, 3])](Subscript[𝒜, 11])-(SubPlus[g])[(Subscript[τ, 1])](SubMinus[g])[(Subscript[τ, 1])(Subscript[τ, 2])/(Subscript[τ, 3])](Subscript[𝒜, 22])≡(SubMinus[g])[(Subscript[τ, 3]^2)/(Subscript[τ, 1]^2)](Subscript[𝒜, ∅])

The Naik-Stanford Double Delta Move and Virtual Versions (Archibald)

=

Timing[𝒜@{(Subscript[X, 6,10,28,24])[w,v],(Subscript[(OverBar[X]), 28,3,29,19])[w,v],(Subscript[X, 26,20,27,19])[w,v],(Subscript[(OverBar[X]), 27,23,11,24])[w,v],(Subscript[X, 1,12,13,30])[u,w],(Subscript[(OverBar[X]), 13,5,14,25])[u,w],(Subscript[X, 17,26,18,25])[u,w],(Subscript[(OverBar[X]), 18,29,8,30])[u,w],(Subscript[X, 4,7,22,15])[v,u],(Subscript[(OverBar[X]), 22,2,23,16])[v,u],(Subscript[X, 20,17,21,16])[v,u],(Subscript[(OverBar[X]), 21,14,9,15])[v,u]}≡𝒜@{(Subscript[X, 5,9,25,21])[w,v],(Subscript[(OverBar[X]), 25,4,26,22])[w,v],(Subscript[X, 29,23,30,22])[w,v],(Subscript[(OverBar[X]), 30,20,12,21])[w,v],(Subscript[X, 2,11,16,27])[u,w],(Subscript[(OverBar[X]), 16,6,17,28])[u,w],(Subscript[X, 14,29,15,28])[u,w],(Subscript[(OverBar[X]), 15,26,7,27])[u,w],(Subscript[X, 3,8,19,18])[v,u],(Subscript[(OverBar[X]), 19,1,20,13])[v,u],(Subscript[X, 23,14,24,13])[v,u],(Subscript[(OverBar[X]), 24,17,10,18])[v,u]}]

𝒜@{(Subscript[X, 1,8,11,3])[u,v],(Subscript[(OverBar[X]), 11,2,12,7])[u,v],(Subscript[X, 12,10,13,4])[u,w],(Subscript[(OverBar[X]), 13,5,6,9])[u,w]} ≡𝒜@{(Subscript[X, 1,10,11,4])[u,w],(Subscript[(OverBar[X]), 11,5,12,9])[u,w],(Subscript[X, 12,8,13,3])[u,v],(Subscript[(OverBar[X]), 13,2,6,7])[u,v]}

𝒜@{(Subscript[(OverBar[X]), 20,1,10,13])[v,u],(Subscript[X, 3,14,19,13])[v,u],(Subscript[X, 14,11,15,21])[u,w],(Subscript[(OverBar[X]), 15,6,7,22])[u,w],
(Subscript[X, 2,12,16,22])[u,w],(Subscript[(OverBar[X]), 16,5,17,21])[u,w], (Subscript[(OverBar[X]), 19,17,9,18])[v,u],(Subscript[X, 4,8,20,18])[v,u]}≡𝒜@{(Subscript[X, 1,11,13,21])[u,w],(Subscript[(OverBar[X]), 13,6,14,22])[u,w],(Subscript[(OverBar[X]), 20,14,10,15])[v,u],(Subscript[X, 3,7,19,15])[v,u],
(Subscript[(OverBar[X]), 19,2,9,16])[v,u],(Subscript[X, 4,17,20,16])[v,u],(Subscript[X, 17,12,18,22])[u,w],(Subscript[(OverBar[X]), 18,5,8,21])[u,w]}

Γ<->𝒜 Conversions

Γ@𝒜[is_,os_,cs_,w_]:=Module[{i,j,ω=Coefficient[w,Wedge[]]},
Γ[is,os,cs,ω,Sum[Cancel[-Coefficient[w,(Subscript[x, j])⋀(Subscript[ξ, i])](Subscript[ξ, i])(Subscript[x, j])/ω], {i,is},{j,os}]]
];
𝒜@Γ[is_,os_,cs_,ω_,λ_]:=𝒜[is,os,cs,Expand[ω WExp[Expand[λ]/.(Subscript[ξ, a_])(Subscript[x, b_]):>(Subscript[ξ, a])⋀(Subscript[x, b])]]];

The conversions are inverses of each other:

γ=Γ[{1,2,3},{1,2,3},{(Subscript[x, 1])->(Subscript[τ, 1]),(Subscript[x, 2])->(Subscript[τ, 2]),(Subscript[x, 3])->(Subscript[τ, 3]),(Subscript[ξ, 1])->(Subscript[τ, 1]),(Subscript[ξ, 2])->(Subscript[τ, 2]),(Subscript[ξ, 3])->(Subscript[τ, 3])},ω,(Subscript[a, 11]) (Subscript[x, 1]) (Subscript[ξ, 1])+(Subscript[a, 12]) (Subscript[x, 2]) (Subscript[ξ, 1])+(Subscript[a, 13]) (Subscript[x, 3]) (Subscript[ξ, 1])+(Subscript[a, 21]) (Subscript[x, 1]) (Subscript[ξ, 2])+(Subscript[a, 22]) (Subscript[x, 2]) (Subscript[ξ, 2])+(Subscript[a, 23]) (Subscript[x, 3]) (Subscript[ξ, 2])+(Subscript[a, 31]) (Subscript[x, 1]) (Subscript[ξ, 3])+(Subscript[a, 32]) (Subscript[x, 2]) (Subscript[ξ, 3])+(Subscript[a, 33]) (Subscript[x, 3]) (Subscript[ξ, 3])];
Γ@𝒜@γ==γ

The Slant Product

Unprotect[Conjugate];
((T^(p_.)))\[Conjugate]:=(T^(-p));
Protect[Conjugate];

WP[Wedge[u___],Wedge[v___]]:=Signature[{u,v}]*Wedge@@Sort[{u,v}];
WP[0,_]=WP[_,0]=0;
WP[A_,B_]:=Expand[Distribute[A ** B] /. (a_. * u_Wedge) ** (b_. * v_Wedge):>a b WP[u,v]];

ep[a_,b_]:=If[a===b,1,0];

(Subscript[Slant, p_])[u_Wedge,v_Wedge]:=Module[{n=Length@u,k=Length@v},
If[n<k,0,
Sum[Signature[σ]*Times@@MapThread[p,{List@@u[[σ]],List@@v}]*Delete[u,List/@σ],
{σ,Permutations[Range@n,{k}]}]
]
];
(Subscript[Slant, _])[0,_]=(Subscript[Slant, _])[_,0]=0;
(Subscript[Slant, p_])[A_,B_]:=Expand[Distribute[A ** B] /. (a_. * u_Wedge) ** (b_. * v_Wedge):>a b\[Conjugate] (Subscript[Slant, p])[u,v]];

(Subscript[Slant, ep])[Wedge[1,2,3,4],Wedge[4,2]+7Wedge[4,1,2]+T Wedge[2]]

The Pairings

(Subscript[p, ς_])[c_,d_]:=Expand@Cancel[(T^(1/2))(((T-1))^(-1))Module[{e,f},
Expand[c(d/.{T->T\[Conjugate],(Subscript[ξ, i_]):>(Subscript[ξ, i])\[Conjugate],(Subscript[x, i_]):>(Subscript[x, i])\[Conjugate]})]/.{(Subscript[t, i_])\[Conjugate](Subscript[t, i_])->0, (Subscript[x, i_])\[Conjugate](Subscript[x, i_])->T-T\[Conjugate],(Subscript[(f:ξ|x), j_])\[Conjugate](Subscript[(e:ξ|x), i_]):>If[Position[ς,(Subscript[e, i])][[1,1]]<Position[ς,(Subscript[f, j])][[1,1]],T-1,1-T\[Conjugate]]}
]];

𝒜[(Subscript[X, 1,2,3,4])[T,T]]

ς0={(Subscript[ξ, 1]),(Subscript[x, 2]),(Subscript[x, 3]),(Subscript[ξ, 4])};
(Subscript[Slant, (Subscript[p, ς0])])[Wedge@@ς0,Last@𝒜[(Subscript[X, 1,2,3,4])[T,T]]]

((T^(-5/2))-(T^(-3/2)))WExp@Expand[((((T^(-5/2))-(T^(-3/2))))^(-1))((((Subscript[x, 2])⋀(Subscript[x, 3]))/(T^(3/2)))-(((Subscript[x, 2])⋀(Subscript[x, 3]))/(Sqrt[T]))+(((Subscript[x, 2])⋀(Subscript[ξ, 4]))/(T^(3/2)))-(((Subscript[x, 2])⋀(Subscript[ξ, 4]))/(Sqrt[T]))+2 (Sqrt[T]) (Subscript[x, 2])⋀(Subscript[ξ, 4])-(T^(3/2)) (Subscript[x, 2])⋀(Subscript[ξ, 4])+(Sqrt[T]) (Subscript[x, 3])⋀(Subscript[ξ, 4])+(((Subscript[ξ, 1])⋀(Subscript[x, 2]))/(T^(3/2)))-((3 (Subscript[ξ, 1])⋀(Subscript[x, 2]))/(Sqrt[T]))+(Sqrt[T]) (Subscript[ξ, 1])⋀(Subscript[x, 2])+(((Subscript[ξ, 1])⋀(Subscript[x, 3]))/(T^(3/2)))-((2 (Subscript[ξ, 1])⋀(Subscript[x, 3]))/(Sqrt[T]))+(((Subscript[ξ, 1])⋀(Subscript[ξ, 4]))/(T^(3/2)))-(((Subscript[ξ, 1])⋀(Subscript[ξ, 4]))/(Sqrt[T]))+(Sqrt[T]) (Subscript[ξ, 1])⋀(Subscript[ξ, 4])-(T^(3/2)) (Subscript[ξ, 1])⋀(Subscript[ξ, 4]))]//Simplify//Expand