Introducing the q-Casimir w to all orders and expressing and computing the invariant in terms of it.

Pensieve header: By Roland, June 20, 2020.

Once[<<KnotTheory`];

(Subscript[PP, _])=Identity; $k=0;γ=1;ℏ=1;

The “Speedy” Engine

Internal Utilities

Canonical Form:

CCF[ℰ_] := ExpandDenominator@ExpandNumerator@Together[
Expand[ℰ] //. (E^(x_))(E^(y_)):>(E^(x+y)) /. (E^(x_)):>(E^(CCF[x]))];
CF[ℰ_List]:=CF/@ℰ;
CF[sd_SeriesData] := MapAt[CF,sd,3];
CF[ℰ_] := Module[
{vs=Cases[ℰ,(Subscript[(y|b|t|a|w|x|η|β|τ|α|ω|ξ), _]),∞]⋃{y,b,t,a,w,x,η,β,τ,α,ω,ξ}},
Total[CoefficientRules[Expand[ℰ], vs] /. (ps_->c_) :> CCF[c](Times@@(vs^ps))]
];
CF[ℰ_𝔼]:=CF/@ℰ; CF[(Subscript[𝔼, sp___])[ℰs___]]:=CF/@(Subscript[𝔼, sp])[ℰs];

The Kronecker δ:

Kδ/:(Subscript[Kδ, i_,j_]):=If[i===j,1,0];

Equality, multiplication, and degree-adjustment of perturbed Gaussians; 𝔼[L,Q,P] stands for (e^(L+Q))P:

𝔼/:𝔼[L1_,Q1_,P1_]≡𝔼[L2_,Q2_,P2_]:=CF[L1==L2]∧CF[Q1==Q2]∧CF[Normal[P1-P2]==0];
𝔼/:𝔼[L1_,Q1_,P1_]𝔼[L2_,Q2_,P2_]:=𝔼[L1+L2,Q1+Q2,P1*P2];
(Subscript[𝔼[L_,Q_,P_], $k_]):=𝔼[L,Q,Series[Normal@P,{ϵ,0,$k}]];

Zip and Bind

Variables and their duals:

{(SuperStar[t]),(SuperStar[b]),(SuperStar[y]),(SuperStar[a]),(SuperStar[w]),(SuperStar[x]),(SuperStar[z])}={τ,β,η,α,ω,ξ,ζ}; 
{(SuperStar[τ]),(SuperStar[β]),(SuperStar[η]),(SuperStar[α]),(SuperStar[ω]),(SuperStar[ξ]),(SuperStar[ζ])}={t,b,y,a,w,x,z}; (SuperStar[((Subscript[u_, i_]))]):=(Subscript[((SuperStar[u])), i]);

Upper to lower and lower to Upper:

U2l={(Subscript[B, i_]^(p_.)):>(E^(-p ℏ γ (Subscript[b, i]))),(B^(p_.)):>(E^(-p ℏ γ b)), (Subscript[T, i_]^(p_.)):>(E^(-p ℏ (Subscript[t, i]))),(T^(p_.)):>(E^(-p ℏ t)),(Subscript[𝒜, i_]^(p_.)):>(E^(p γ (Subscript[α, i]))),(𝒜^(p_.)):>(E^(p γ α)),(Subscript[Ω, i_]^(p_.)):>(E^(p  (Subscript[ω, i]))),(Ω^(p_.)):>(E^(p  ω))}; 
l2U={(E^(c_.(Subscript[b, i_])+d_.)):>(Subscript[B, i]^(-c/(ℏ γ)))(E^d),(E^(c_.b+d_.)):>(B^(-c/(ℏ γ)))(E^d),
(E^(c_.(Subscript[t, i_])+d_.)):>(Subscript[T, i]^(-c/ℏ))(E^d),(E^(c_.t+d_.)):>(T^(-c/ℏ))(E^d),
(E^(c_.(Subscript[α, i_])+d_.)):>(Subscript[𝒜, i]^(c/γ))(E^d),(E^(c_.α+d_.)):>(𝒜^(c/γ))(E^d),
(E^(c_.(Subscript[ω, i_])+d_.)):>(Subscript[Ω, i]^c)(E^d),(E^(c_.ω+d_.)):>(Ω^c)(E^d),
(E^(ℰ_)):>(E^(Expand@ℰ))};

Derivatives in the presence of exponentiated variables:

(Subscript[D, b])[f_]:=(∂_b)f-ℏ γ B(∂_B)f; (Subscript[D, (Subscript[b, i_])])[f_]:=(∂_(Subscript[b, i]))f-ℏ γ (Subscript[B, i])(∂_(Subscript[B, i]))f;
(Subscript[D, t])[f_]:=(∂_t)f-ℏ T(∂_T)f; (Subscript[D, (Subscript[t, i_])])[f_]:=(∂_(Subscript[t, i]))f-ℏ (Subscript[T, i])(∂_(Subscript[T, i]))f; 
(Subscript[D, α])[f_]:=(∂_α)f+γ 𝒜 (∂_𝒜)f; (Subscript[D, (Subscript[α, i_])])[f_]:=(∂_(Subscript[α, i]))f+γ (Subscript[𝒜, i]) (∂_(Subscript[𝒜, i]))f;
(Subscript[D, ω])[f_]:=(∂_ω)f+ Ω (∂_Ω)f; (Subscript[D, (Subscript[ω, i_])])[f_]:=(∂_(Subscript[ω, i]))f+ (Subscript[Ω, i]) (∂_(Subscript[Ω, i]))f;
(Subscript[D, v_])[f_]:=(∂_v)f; (Subscript[D, {v_,0}])[f_]:=f; (Subscript[D, {}])[f_]:=f; (Subscript[D, {v_,n_Integer}])[f_]:=(Subscript[D, v])[(Subscript[D, {v,n-1}])[f]];
(Subscript[D, {l_List,ls___}])[f_]:=(Subscript[D, {ls}])[(Subscript[D, l])[f]];

Finite Zips:

collect[sd_SeriesData, ζ_] := MapAt[collect[#,ζ]&,sd,3];
collect[ℰ_,ζ_] := Collect[ℰ,ζ];
(Subscript[Zip, {}])[P_]:=P;
(Subscript[Zip, ζs_])[Ps_List]:=(Subscript[Zip, ζs])/@Ps;
(Subscript[Zip, {ζ_,ζs___}])[P_] := 
(collect[P//(Subscript[Zip, {ζs}]),ζ] /. f_.(ζ^(d_.)):>((Subscript[D, {(SuperStar[ζ]),d}])[f]))/.(SuperStar[ζ])->0/.(((SuperStar[ζ])/.{b->B,t->T,α->𝒜,ω->Ω})->1)

QZip implements the “Q-level zips” on 𝔼(L,Q,P)=(e^(L+Q))P(ϵ). Such zips regard the L variables as scalars.

(Subscript[QZip, ζs_List])@𝔼[L_,Q_,P_] := Module[{ζ,z,zs,c,ys,ηs,qt,zrule,ζrule,out},
zs=Table[(SuperStar[ζ]),{ζ,ζs}];
c=CF[Q/.Alternatives@@(ζs⋃zs)->0];
ys=CF@Table[(∂_ζ)(Q/.Alternatives@@zs->0),{ζ,ζs}];
ηs=CF@Table[(∂_z)(Q/.Alternatives@@ζs->0),{z,zs}];
qt=CF@Inverse@Table[(Subscript[Kδ, z,(SuperStar[ζ])])-(∂_(z,ζ))Q,{ζ,ζs},{z,zs}];
zrule=Thread[zs->CF[qt.(zs+ys)]];
ζrule=Thread[ζs->ζs+ηs.qt];
CF /@ 𝔼[L,c+ηs.qt.ys,Det[qt](Subscript[Zip, ζs])[P/.(zrule⋃ζrule)]] ];

LZip implements the “L-level zips” on 𝔼(L,Q,P)=((Pe)^(L+Q)). Such zips regard all of ((Pe)^Q) as a single”P”. Here the z’s are b and α and the ζ’s are β and a.

(Subscript[LZip, ζs_List])@𝔼[L_,Q_,P_] := Module[{ζ,z,zs,Zs,c,ys,ηs,lt,zrule,Zrule,ζrule,Q1,EEQ,EQ},
(*Print["LZip"];*)
zs=Table[(SuperStar[ζ]),{ζ,ζs}];
Zs=zs/.{b->B,t->T,α->𝒜,ω->Ω};
c=L/.Alternatives@@(ζs⋃zs)->0/.Alternatives@@Zs->1;
ys=Table[(∂_ζ)(L/.Alternatives@@zs->0),{ζ,ζs}];
ηs=Table[(∂_z)(L/.Alternatives@@ζs->0),{z,zs}];
lt=Inverse@Table[(Subscript[Kδ, z,(SuperStar[ζ])])-(∂_(z,ζ))L,{ζ,ζs},{z,zs}];
zrule=Thread[zs->lt.(zs+ys)];
Zrule=Join[zrule,zrule/.r_Rule:>((U=r[[1]]/.{b->B,t->T,α->𝒜,ω->Ω})->(U/.U2l/.r//.l2U))];
ζrule=Thread[ζs->ζs+ηs.lt];
Q1=Q/.(Zrule⋃ζrule);
EEQ[ps___]:=EEQ[ps]=(CF[(E^(-Q1))(Subscript[D, Thread[{zs,{ps}}]])[(E^Q1)]]/.{Alternatives@@zs->0,Alternatives@@Zs->1});
CF@𝔼[c+ηs.lt.ys,Q1/.{Alternatives@@zs->0,Alternatives@@Zs->1},
Det[lt]((Subscript[Zip, ζs])[(EQ@@zs)(P/.(Zrule⋃ζrule))] /. Derivative[ps___][EQ][___] :> EEQ[ps] /. _EQ->1)  ] ];

(Subscript[TZip, ζs_List])@𝔼[L_,Q_,P_] := Module[{ζ,z,zs,Zs,c,ys,ηs,lt,zrule,Zrule,ζrule,Q1,EEQ,EQ,Lnew=L,Qnew=Q,Pnew=P},
zrule = Table[(SuperStar[ζ])->Coefficient[L,ζ],{ζ,ζs}];
(*Print["Tzip"];*)
ζrule = Table[ζ->0,{ζ,ζs}];
Lnew=L/.U2l/.zrule/.ζrule;
Qnew=Q/.U2l/.zrule/.ζrule;(**)
Pnew=P/.U2l/.zrule/.ζrule;
CF@(𝔼[Lnew,Qnew,Pnew]//.l2U)
];

(Subscript[B, {}])[L_,R_]:=L R;
(Subscript[B, {is__}])[L_𝔼,R_𝔼] := Module[{n},
Times[
L/.Table[(Subscript[(v:b|B|t|T|a|w|x|y), i])->(Subscript[v, n@i]),{i,{is}}],
R/.Table[(Subscript[(v:β|τ|α|𝒜|ω|Ω|ξ|η), i])->(Subscript[v, n@i]),{i,{is}}]
]// (Subscript[TZip, Join@@Table[{(Subscript[τ, n@i])},{i,{is}}]]) // (Subscript[LZip, Join@@Table[{(Subscript[w, n@i]),(Subscript[β, n@i]),(Subscript[a, n@i])},{i,{is}}]]) // (Subscript[QZip, Join@@Table[{(Subscript[ξ, n@i]),(Subscript[y, n@i])},{i,{is}}]]) ];(**)
(Subscript[B, is___])[L_,R_]:=(Subscript[B, {is}])[L,R];

𝔼 morphisms with domain and range.

(Subscript[B, is_List])[(Subscript[𝔼, d1_->r1_])[L1_,Q1_,P1_],(Subscript[𝔼, d2_->r2_])[L2_,Q2_,P2_]]:=(Subscript[𝔼, (d1⋃Complement[d2,is])->(r2⋃Complement[r1,is])])@@(Subscript[B, is])[𝔼[L1,Q1,P1],𝔼[L2,Q2,P2]];
(Subscript[𝔼, d1_->r1_])[L1_,Q1_,P1_]//(Subscript[𝔼, d2_->r2_])[L2_,Q2_,P2_] := (Subscript[B, r1⋂d2])[(Subscript[𝔼, d1->r1])[L1,Q1,P1],(Subscript[𝔼, d2->r2])[L2,Q2,P2]];
(Subscript[𝔼, d1_->r1_])[L1_,Q1_,P1_]≡(Subscript[𝔼, d2_->r2_])[L2_,Q2_,P2_] ^:= (d1==d2)∧(r1==r2)∧(𝔼[L1,Q1,P1]≡𝔼[L2,Q2,P2]);
(Subscript[𝔼, d1_->r1_])[L1_,Q1_,P1_](Subscript[𝔼, d2_->r2_])[L2_,Q2_,P2_] ^:= (Subscript[𝔼, (d1⋃d2)->(r1⋃r2)])@@(𝔼[L1,Q1,P1]𝔼[L2,Q2,P2]);
(Subscript[(Subscript[𝔼, dr_])[L_,Q_,P_], $k_]):=(Subscript[𝔼, dr])@@(Subscript[𝔼[L,Q,P], $k]);
(Subscript[𝔼, _])[ℰ___][i_]:={ℰ}[[i]];

𝔼[Λ]

(Subscript[𝔼, dr_])[Λ_]:=CF@Module[{L,Λ0=Limit[Λ,ϵ->0]},(Subscript[(Subscript[𝔼, dr])[L=Λ0 /. (Subscript[(η|y|ξ|x), _])->0,Λ0-L,(E^(Λ-Λ0))], $k])/.l2U]

“Define” Code

Define[lhs=rhs, ...] defines the lhs to be rhs, except that rhs is computed only once for each value of $k. Fancy Mathematica not for the faint of heart. Most readers should ignore.

SetAttributes[Define, HoldAll];
Define[def_,defs__] := (Define[def]; Define[defs];);
Define[(Subscript[op_, is__])=ℰ_] := Module[{SD,ii,jj,kk,isp,nis,nisp,sis},Block[{i,j,k},
ReleaseHold[Hold[
SD[(Subscript[op, nisp,$k_Integer]),Block[{i,j,k},(Subscript[op, isp,$k])=ℰ;(Subscript[op, nis,$k])]];
SD[(Subscript[op, isp]),(Subscript[op, {is},$k])]; SD[(Subscript[op, sis__]),(Subscript[op, {sis}])];
]/. {SD->SetDelayed,
isp->{is}/.{i->i_,j->j_,k->k_},
nis->{is}/.{i->ii,j->jj,k->kk},
nisp->{is}/.{i->ii_,j->jj_,k->kk_}
}]  ]]

Symmetric Algebra Objects

(Subscript[sm, i_,j_->k_]):=(Subscript[𝔼, {i,j}->{k}])[(Subscript[b, k])((Subscript[β, i])+(Subscript[β, j]))+(Subscript[t, k])((Subscript[τ, i])+(Subscript[τ, j]))+(Subscript[a, k])((Subscript[α, i])+(Subscript[α, j]))+(Subscript[y, k])((Subscript[η, i])+(Subscript[η, j]))+(Subscript[x, k])((Subscript[ξ, i])+(Subscript[ξ, j]))];
(Subscript[sΔ, i_->j_,k_]):=(Subscript[𝔼, {i}->{j,k}])[(Subscript[β, i])((Subscript[b, j])+(Subscript[b, k]))+(Subscript[τ, i])((Subscript[t, j])+(Subscript[t, k]))+(Subscript[α, i])((Subscript[a, j])+(Subscript[a, k]))+(Subscript[η, i])((Subscript[y, j])+(Subscript[y, k]))+(Subscript[ξ, i])((Subscript[x, j])+(Subscript[x, k]))];
(Subscript[sS, i_]):=(Subscript[𝔼, {i}->{i}])[-(Subscript[β, i])(Subscript[b, i])-(Subscript[τ, i])(Subscript[t, i])-(Subscript[α, i])(Subscript[a, i])-(Subscript[η, i])(Subscript[y, i])-(Subscript[ξ, i])(Subscript[x, i])];
(Subscript[sϵ, i_]):=(Subscript[𝔼, {}->{i}])[0];(Subscript[sη, i_]):=(Subscript[𝔼, {i}->{}])[0];

(Subscript[sσ, i_->j_]):=(Subscript[𝔼, {i}->{j}])[(Subscript[β, i])(Subscript[b, j])+(Subscript[τ, i])(Subscript[t, j])+(Subscript[α, i])(Subscript[a, j])+(Subscript[η, i])(Subscript[y, j])+(Subscript[ξ, i])(Subscript[x, j])];
(Subscript[sΥ, i_->j_,k_,l_,m_]):=(Subscript[𝔼, {i}->{j,k,l,m}])[(Subscript[β, i])(Subscript[b, k])+(Subscript[τ, i])(Subscript[t, k])+(Subscript[α, i])(Subscript[a, l])+(Subscript[η, i])(Subscript[y, j])+(Subscript[ξ, i])(Subscript[x, m])];

Booting Up QU

Define[(Subscript[aσ, i->j])=(Subscript[𝔼, {i}->{j}])[(Subscript[a, j]) (Subscript[α, i])+(Subscript[x, j]) (Subscript[ξ, i])],(Subscript[bσ, i->j])=(Subscript[𝔼, {i}->{j}])[(Subscript[b, j]) (Subscript[β, i])+(Subscript[y, j]) (Subscript[η, i])]]

Define[(Subscript[am, i,j->k])=(Subscript[𝔼, {i,j}->{k}])[((Subscript[α, i])+(Subscript[α, j]))(Subscript[a, k])+((Subscript[𝒜, j]^(-1))(Subscript[ξ, i])+(Subscript[ξ, j]))(Subscript[x, k])],
(Subscript[bm, i,j->k])=(Subscript[𝔼, {i,j}->{k}])[((Subscript[β, i])+(Subscript[β, j]))(Subscript[b, k])+((Subscript[η, i])+(E^(- ϵ (Subscript[β, i])))(Subscript[η, j]))(Subscript[y, k])]]

Three types of inverses appear below!
(OverBar[R]) is the inverse of R in the algebra 𝔹⊗𝔸.
P is the inverse of R as a quadratic form, like how an element of (SuperStar[V])⊗(SuperStar[V]) can be the inverse of an element of V⊗V.
(OverBar[aS]) is the inverse of aS as an operator form, like how an element of (SuperStar[V])⊗V can be the inverse of another element of (SuperStar[V])⊗V.

Define[(Subscript[R, i,j])=(Subscript[𝔼, {}->{i,j}])[ℏ (Subscript[a, j]) (Subscript[b, i])+(∑_(k=1)^($k+1)) (((((1-(E^(γ ϵ ℏ))))^k)(((ℏ (Subscript[y, i])(Subscript[x, j])))^k))/(k(1-(E^(k γ ϵ ℏ)))))],
(Subscript[(OverBar[R]), i,j])=CF@(Subscript[𝔼, {}->{i,j}])[-ℏ (Subscript[a, j]) (Subscript[b, i]),-ℏ (Subscript[x, j]) (Subscript[y, i])/(Subscript[B, i]),1+If[$k==0, 0,(Subscript[((Subscript[(OverBar[R]), {i,j},$k-1])), $k])[3]-
(((Subscript[((Subscript[(OverBar[R]), {i,j},0])), $k])(Subscript[R, 1,2])(Subscript[((Subscript[(OverBar[R]), {3,4},$k-1])), $k]))//((Subscript[bm, i,1->i])(Subscript[am, j,2->j]))//((Subscript[bm, i,3->i])(Subscript[am, j,4->j])))[3]]],
(Subscript[P, i,j])=(Subscript[𝔼, {i,j}->{}])[(Subscript[β, i])(Subscript[α, j])/ℏ,(Subscript[η, i])(Subscript[ξ, j])/ℏ,1+If[$k==0,0,(Subscript[((Subscript[P, {i,j},$k-1])), $k])[3]-
((Subscript[R, 1,2])//((Subscript[((Subscript[P, {1,j},0])), $k])(Subscript[((Subscript[P, {i,2},$k-1])), $k])))[3]]]]

Define[(Subscript[aS, i])=((Subscript[aσ, i->2])(Subscript[(OverBar[R]), 1,i]))//(Subscript[P, 1,2]),
(Subscript[(OverBar[aS]), i])=(Subscript[𝔼, {i}->{i}])[-(Subscript[a, i]) (Subscript[α, i]),-(Subscript[x, i]) (Subscript[𝒜, i]) (Subscript[ξ, i]),1+If[$k==0, 0,(Subscript[((Subscript[(OverBar[aS]), {i},$k-1])), $k])[3]-
((Subscript[((Subscript[(OverBar[aS]), {i},0])), $k])//(Subscript[aS, i])//(Subscript[((Subscript[(OverBar[aS]), {i},$k-1])), $k]))[3]]]]

(was (Subscript[aS, j])=(Subscript[(OverBar[R]), i,j])~(Subscript[B, i])~(Subscript[P, i,j])).

Define[(Subscript[bS, i])=(Subscript[bσ, i->1])(Subscript[R, i,2])//(Subscript[aS, 2])//(Subscript[P, 1,2]),
(Subscript[(OverBar[bS]), i])=(Subscript[bσ, i->1])(Subscript[R, i,2])//(Subscript[(OverBar[aS]), 2])//(Subscript[P, 1,2]),
(Subscript[aΔ, i->j,k])=((Subscript[R, 1,j])(Subscript[R, 2,k]))//(Subscript[bm, 1,2->3])//(Subscript[P, 3,i]),
(Subscript[bΔ, i->j,k])=((Subscript[R, j,1])(Subscript[R, k,2]))//(Subscript[am, 1,2->3])//(Subscript[P, i,3])]

(was (Subscript[bS, i])=(Subscript[R, i,1])~(Subscript[B, 1])~(Subscript[aS, 1])~(Subscript[B, 1])~(Subscript[P, i,1]),(Subscript[(OverBar[bS]), i])=(Subscript[R, i,1])~(Subscript[B, 1])~(Subscript[(OverBar[aS]), 1])~(Subscript[B, 1])~(Subscript[P, i,1])).

The Drinfel’d double:

Define[(Subscript[dm, i,j->k])=(((Subscript[sΥ, i->4,4,1,1])//(Subscript[aΔ, 1->1,2])//(Subscript[aΔ, 2->2,3])//(Subscript[(OverBar[aS]), 3]))((Subscript[sΥ, j->-1,-1,-4,-4])//(Subscript[bΔ, -1->-1,-2])//(Subscript[bΔ, -2->-2,-3])))//((Subscript[P, -1,3])(Subscript[P, -3,1])(Subscript[am, 2,-4->k])(Subscript[bm, 4,-2->k]))]

Define[(Subscript[dσ, i->j])=(Subscript[aσ, i->j])(Subscript[bσ, i->j]),
(Subscript[dϵ, i])=(Subscript[sϵ, i]), (Subscript[dη, i])=(Subscript[sη, i]),
(Subscript[dS, i])=(Subscript[sΥ, i->1,1,2,2])//((Subscript[(OverBar[bS]), 1])(Subscript[aS, 2]))//(Subscript[dm, 2,1->i]),
(Subscript[(OverBar[dS]), i])=(Subscript[sΥ, i->1,1,2,2])//((Subscript[bS, 1])(Subscript[(OverBar[aS]), 2]))//(Subscript[dm, 2,1->i]),
(Subscript[dΔ, i->j,k])=((Subscript[bΔ, i->3,1])(Subscript[aΔ, i->2,4]))//((Subscript[dm, 3,4->k])(Subscript[dm, 1,2->j]))]

Define[(Subscript[C, i])=(Subscript[(Subscript[𝔼, {}->{i}])[0,0,(Subscript[B, i]^(1/2))(E^(-ℏ ϵ (Subscript[a, i])/2))], $k]),
(Subscript[(OverBar[C]), i])=(Subscript[(Subscript[𝔼, {}->{i}])[0,0,(Subscript[B, i]^(-1/2))(E^(ℏ ϵ (Subscript[a, i])/2))], $k]),
(Subscript[Kink, i]) = ((Subscript[R, 1,3])(Subscript[(OverBar[C]), 2]))//(Subscript[dm, 1,2->1])//(Subscript[dm, 1,3->i]),
(Subscript[(OverBar[Kink]), i]) = ((Subscript[(OverBar[R]), 1,3])(Subscript[C, 2]))//(Subscript[dm, 1,2->1])//(Subscript[dm, 1,3->i])]

Note. t=-ϵa+γb and b=t/γ+ϵa/γ

Define[(Subscript[b2t, i])=(Subscript[𝔼, {i}->{i}])[(Subscript[α, i])(Subscript[a, i])+(Subscript[β, i])(ϵ (Subscript[a, i])+(Subscript[t, i]))/γ+(Subscript[ξ, i])(Subscript[x, i])+(Subscript[η, i])(Subscript[y, i])],
(Subscript[t2b, i])=(Subscript[𝔼, {i}->{i}])[(Subscript[α, i])(Subscript[a, i])+(Subscript[τ, i])(-ϵ (Subscript[a, i])+γ (Subscript[b, i]))+(Subscript[ξ, i])(Subscript[x, i])+(Subscript[η, i])(Subscript[y, i])]]

The t-Tensors

Define[(Subscript[tR, i,j])=(Subscript[R, i,j])//((Subscript[b2t, i])(Subscript[b2t, j])),
(Subscript[(OverBar[tR]), i,j])=(Subscript[(OverBar[R]), i,j])//((Subscript[b2t, i])(Subscript[b2t, j])) ,
(Subscript[tm, i,j->k])=(((Subscript[t2b, i])(Subscript[t2b, j]))//(Subscript[dm, i,j->k])//(Subscript[b2t, k]) ),
(Subscript[tC, i])=((Subscript[C, i])//(Subscript[b2t, i]) ),
(Subscript[(OverBar[tC]), i])=((Subscript[(OverBar[C]), i])//(Subscript[b2t, i]) ),
(Subscript[tKink, i])=(Subscript[Kink, i])//(Subscript[b2t, i]) ,
(Subscript[(OverBar[tKink]), i])=(Subscript[(OverBar[Kink]), i])//(Subscript[b2t, i]) ,
(Subscript[tΔ, i->j,k])=(Subscript[t2b, i])//(Subscript[dΔ, i->j,k])//((Subscript[b2t, j])(Subscript[b2t, k])),
(Subscript[tS, i])=(Subscript[t2b, i])//(Subscript[dS, i])//(Subscript[b2t, i])]

The w-Tensors

Use the central variable w = (1/2)+a+((x y)/(1-T))

(Subscript[a2w, i_]):=(Subscript[𝔼, {i}->{i}])[(Subscript[τ, i])(Subscript[t, i])+(Subscript[α, i])(((-1)/2)+(Subscript[w, i]) ),((E^(-(Subscript[α, i])))-1)(((Subscript[y, i])(Subscript[x, i]))/(1-(Subscript[T, i])))+(Subscript[ξ, i])(Subscript[x, i])+(Subscript[η, i])(Subscript[y, i]),1]
(Subscript[w2a, i_]):=(Subscript[𝔼, {i}->{i}])[(Subscript[τ, i])(Subscript[t, i])+((Subscript[a, i])+(1/2))(Subscript[ω, i]),(((1-(E^(-(Subscript[ω, i])))))/(1-(Subscript[T, i])))(Subscript[y, i])(Subscript[x, i])+(Subscript[ξ, i])(Subscript[x, i])+(Subscript[η, i])(Subscript[y, i]),1]

(Subscript[𝔼, {}->{i,j}])[0,0,(Subscript[x, i])(Subscript[y, j])-(Subscript[x, j])(Subscript[y, i])]//(Subscript[wm, i,j->k])

Up to some notational annoyance the kink is exp(tw)

(Subscript[tKink, i])//(Subscript[a2w, i])
(Subscript[(OverBar[tKink]), i])//(Subscript[a2w, i])

The R-matrix becomes complicated! I also rescaling x by xnew = (((1-T))^(-1))xold will help

(Subscript[tR, i,j])//(Subscript[a2w, i])//(Subscript[a2w, j])
(Subscript[(OverBar[tR]), i,j])//(Subscript[a2w, i])//(Subscript[a2w, j])
(Subscript[w2a, i])//(Subscript[w2a, j])//(Subscript[tm, i,j->k])//(Subscript[a2w, k])
(Subscript[tC, i])//(Subscript[a2w, i])
(Subscript[(OverBar[tC]), i])//(Subscript[a2w, i])

So let’s define the newly found building blocks independently: (recall T = exp(-t) so the annoying -(t/2) in the L part is really Sqrt[T] in the P part.)
(not quite sure I did the rescaling correctly (why would it not be (Subscript[T, j])?))

Define[
(Subscript[wR, i,j])=(Subscript[𝔼, {}->{i,j}])[(Subscript[t, i]) (Subscript[w, j]),(1-(Subscript[T, i]))(Subscript[x, j]) (Subscript[y, i])-(1-(Subscript[T, i]))(Subscript[x, j])(Subscript[y, j]),Sqrt[(Subscript[T, i])]],
(Subscript[(OverBar[wR]), i,j])=(Subscript[𝔼, {}->{i,j}])[-(Subscript[t, i]) (Subscript[w, j]),((-(1-(Subscript[T, i]))(Subscript[x, j]) (Subscript[y, i])+(1-(Subscript[T, i]))(Subscript[y, j])(Subscript[x, j]))/(Subscript[T, i])),(1/(Sqrt[(Subscript[T, i])]))],
(Subscript[wC, i])=(Subscript[𝔼, {}->{i}])[0,0,Sqrt[(Subscript[T, i])]],
(Subscript[(OverBar[wC]), i])=(Subscript[𝔼, {}->{i}])[0,0,(1/(Sqrt[(Subscript[T, i])]))],
(Subscript[wm, i,j->k])=(Subscript[𝔼, {i,j}->{k}])[(Subscript[t, k]) (Subscript[τ, i])+(Subscript[t, k]) (Subscript[τ, j])+(Subscript[w, k]) (Subscript[ω, i])+(Subscript[w, k]) (Subscript[ω, j]),(Subscript[y, k]) (Subscript[η, i])+(Subscript[y, k]) (Subscript[η, j])+(Subscript[x, k]) (Subscript[ξ, i])+(Subscript[η, j]) (Subscript[ξ, i])+(Subscript[x, k]) (Subscript[ξ, j]),1+((O[ϵ])^1)]
]

Almost matching Γ calculus

Checking Reidemeister 1: (it is satisfied up to an overall factor of (e^(+-w t)))

(Subscript[wR, 1,2])(Subscript[(OverBar[wC]), 3])//(Subscript[wm, 1,3->1])//(Subscript[wm, 1,2->1])
(Subscript[(OverBar[wR]), 1,2])(Subscript[wC, 3])//(Subscript[wm, 1,3->1])//(Subscript[wm, 1,2->1])
(Subscript[(OverBar[wR]), 1,2])(Subscript[(OverBar[wC]), 3])//(Subscript[wm, 2,3->2])//(Subscript[wm, 2,1->1])
(Subscript[wR, 1,2])(Subscript[wC, 3])//(Subscript[wm, 2,3->2])//(Subscript[wm, 2,1->1])

Checking Reidemeister 2:

(Subscript[wR, 1,2])(Subscript[(OverBar[wR]), 3,4])//(Subscript[wm, 1,3->1])//(Subscript[wm, 2,4->2])

Checking Reidemeister 3:

((Subscript[wR, 1,2])(Subscript[wR, 4,3])(Subscript[wR, 5,6])//(Subscript[wm, 1,4->1])//(Subscript[wm, 2,5->2])//(Subscript[wm, 3,6->3]))≡
((Subscript[wR, 2,3])(Subscript[wR, 1,6])(Subscript[wR, 4,5])//(Subscript[wm, 1,4->1])//(Subscript[wm, 2,5->2])//(Subscript[wm, 3,6->3]))

Trefoil knot

((Subscript[wR, 5,1])(Subscript[wR, 2,6])(Subscript[wR, 7,3])(Subscript[wC, 4])//(Subscript[wm, 1,2->1])//(Subscript[wm, 1,3->1])//(Subscript[wm, 1,4->1])//(Subscript[wm, 1,5->1])//(Subscript[wm, 1,6->1])//(Subscript[wm, 1,7->1]))

Let’s look at the product in Γ calculus style. Caution: variables γ and ϵ are in use, use g and e instead.
Taking the opposite product gives Γ calc. Provided the matrix A of Γ calculus is written as A=I+Q, where Q is the quadratic
actually used in Gaussian calculus. 
First let’s check out the crossings (Subscript[wR, 1,2]) and (Subscript[(OverBar[wR]), 1,2]) turn into the Γ calc values for the crossings. Except for the annoying? Sqrt[T] factor.
but that’s ok.

Table[Coefficient[(Subscript[wR, 1,2])[[2]],(Subscript[y, i])(Subscript[x, j])],{i,{1,2}},{j,{1,2}}]+IdentityMatrix[2]//FullSimplify//MatrixForm
Table[Coefficient[(Subscript[(OverBar[wR]), 1,2])[[2]],(Subscript[y, i])(Subscript[x, j])],{i,{1,2}},{j,{1,2}}]+IdentityMatrix[2]//FullSimplify//Expand//MatrixForm

(*We start with the matrix *)A=(({{α, β, θ}, {g, δ, ϵ}, {ϕ, ψ, Ξ}})) ;(*and scalar Omega*)

(*Now form the relevant Q =A-I*)
Q={(Subscript[y, a]),(Subscript[y, b]),(Subscript[y, S])}.(A-IdentityMatrix[3]).{(Subscript[x, a]),(Subscript[x, b]),(Subscript[x, S])}//Expand

(*Compute the product in the Gaussian way but OPPOSITE*)
ProdResult=(Subscript[𝔼, {}->{a,b,S}])[0,Q,Omega]//(Subscript[wm, b,a->c])

(*Extract the resulting newQ*)
NewQ = Table[Coefficient[ProdResult[[2]],(Subscript[y, i])(Subscript[x, j])],{i,{c,S}},{j,{c,S}}];
NewQ//MatrixForm;
(*Form the newA = NewQ+I*)
NewA=NewQ+IdentityMatrix[2]//FullSimplify;
NewA//MatrixForm (*et voila, the golden standard comes out.*)