Dror Bar-Natan: Papers: WKO:

The w-Formula for the Alexander Polynomial

We verify that the w-formula for the Alexander polynomial is right for all knots with up to 11 crossings. See also the blackboard shot at http://katlas.math.toronto.edu/drorbn/bbs/show?shot=KAL-090610-144148.jpg.

Pensieve Header: We verify that the w-formula for the Alexander polynomial is right for all knots with up to 11 crossings. See also the blackboard shot at http://katlas.math.toronto.edu/drorbn/bbs/show?shot=KAL-090610-144148.jpg.

<< KnotTheory`

The Program and a Test Run on Knot[8,17]

K=Knot[8,17];
Alexander[K][X]

Generating Gauss Codes

GC[K_] := GC @@ (
PD[K] /. X[i_,j_,k_,l_] :> If[PositiveQ[X[i,j,k,l]],
Ar[l,i,+1], Ar[j,i,-1]
]
)

GC[K]

Generating the Trapping Matrix

Tij[Ar[ti_,hi_,si_], Ar[tj_,hj_,sj_]] := If[
ti<hj<hi || hi<hj<ti,
1,0
];
T[K_] := Module[
{gc=GC[K]},
Outer[Tij,List@@gc, List@@gc]
]

T[K] // MatrixForm

The Diagonal Matrix of Signs S

Si[Ar[ti_,hi_,si_]] := Sign[hi-ti]*si;
S[K_] := DiagonalMatrix[Si /@ (List @@ GC[K])];
S1[K_] := MatrixExp[-Log[X]S[K]] - IdentityMatrix[Crossings[K]]

MatrixForm /@ {S[K], S1[K]}

wA

IdentityMatrix[Crossings[K]] - T[K].S1[K] // MatrixForm

wA[K_] := Det[
IdentityMatrix[Crossings[K]] - T[K].S1[K]
]

wA[K]

A Test Run on Sanderson's 8_17

K1=PD[
X[1,12,2,13],  X[7,2,8,3], X[3,8,4,9], X[11,4,12,5],
X[5,17,6,16], X[13,7,14,6], X[9,15,10,14], X[15,11,16,10]
];

MatrixForm /@ {T[K1], S[K1]}

IdentityMatrix[Crossings[K1]] - T[K1].S1[K1] // MatrixForm

wA[K1]

Testing the Full Rolfsen Table

Test[K_] := (wA[K] == Alexander[K][X])

Union[Test /@ AllKnots[{3,11}]]