Pensieve header: The Splash Program of Figure 1.1, computing $z_1$.

SetDirectory["C:\\drorbn\\AcademicPensieve\\Projects\\PPSA\\PPSA-170103"];

Splash Demo

(Subscript[DP, x_->(Subscript[D, α_]),y_->(Subscript[D, β_])])[P_][f_] := (* means P[(∂_α),(∂_β)][f] *)
Total[CoefficientRules[P, {x,y}] /. ({m_,n_}->c_) :> c D[f,{α,m},{β,n}]];
CF[𝔼[ω_,L_,Q_,P_]] := Expand/@Together/@
𝔼[ω/.b:>Log[t],L,Q/.b:>Log[t],P/.b:>Log[t]];
𝔼 /: 𝔼[ω1_,L1_,Q1_,P1_]𝔼[ω2_,L2_,Q2_,P2_] := CF@𝔼[ω1 ω2, L1+L2,ω2 Q1+ω1 Q2,((ω2)^4)P1+((ω1)^4)P2];
(Subscript[N, (Subscript[u, i_])(Subscript[c, j_])->k_])[𝔼[ω_,L_,Q_,P_]] := With[{q=(E^(-γ))β (Subscript[u, k])+γ (Subscript[c, k])}, CF[
𝔼[ω, γ (Subscript[c, k])+(L/.(Subscript[c, j])->0), ω (E^(-γ))β (Subscript[u, k])+(Q/.(Subscript[u, i])->0), (E^(-q))(Subscript[DP, (Subscript[c, j])->(Subscript[D, γ]),(Subscript[u, i])->(Subscript[D, β])])[P][(E^q)]]/. {γ->(∂_(Subscript[c, j]))L,β->(ω^(-1))(∂_(Subscript[u, i]))Q}]];
(Subscript[N, (Subscript[w, i_])(Subscript[c, j_])->k_])[𝔼[ω_,L_,Q_,P_]] := With[{q=(E^γ)α (Subscript[w, k])+γ (Subscript[c, k])}, CF[
𝔼[ω, γ (Subscript[c, k])+(L/.(Subscript[c, j])->0), ω (E^γ)α (Subscript[w, k])+(Q/.(Subscript[w, i])->0), (E^(-q))(Subscript[DP, (Subscript[c, j])->(Subscript[D, γ]),(Subscript[w, i])->(Subscript[D, α])])[P][(E^q)]]/. {γ->(∂_(Subscript[c, j]))L,α->(ω^(-1))(∂_(Subscript[w, i]))Q}]];
 (Subscript[N, (Subscript[w, i_])(Subscript[u, j_])->k_])[𝔼[ω_,L_,Q_,P_]] :=With[{q=(1-t)(μ^(-1)) α β+(μ^(-1)) β (Subscript[u, k])+(μ^(-1)) δ (Subscript[u, k])(Subscript[w, k])+(μ^(-1)) α (Subscript[w, k])}, CF[
𝔼[μ ω, L, μ ω q+μ(Q/.(Subscript[w, i])|(Subscript[u, j])->0), (μ^4) (E^(-q)) (Subscript[DP, (Subscript[w, i])->(Subscript[D, α]),(Subscript[u, j])->(Subscript[D, β])])[P][(E^q)]+(ω^4)Λ[k]] /. μ->1+(t-1) δ /. {α->(ω^(-1))((∂_(Subscript[w, i]))Q/.(Subscript[u, j])->0), β->(ω^(-1))((∂_(Subscript[u, j]))Q/.(Subscript[w, i])->0), δ->(ω^(-1))(∂_((Subscript[w, i]),(Subscript[u, j])))Q}]];
(Subscript[m, i_,j_->k_])[Z_] :=Module[{x,y,z},
Z// (Subscript[N, (Subscript[w, i])(Subscript[c, j])->x]) // (Subscript[N, (Subscript[w, x])(Subscript[u, j])->y]) // ReplaceAll[{(Subscript[c, x|y])->(Subscript[c, x]),(Subscript[w, j])->(Subscript[w, y])}] // (Subscript[N, (Subscript[u, i])(Subscript[c, x])->x]) // ReplaceAll[(Subscript[z_, i|j|x|y])->(Subscript[z, k])] // CF]

Λ[k_]:=(1-t)((α^2)(β^2)+4α β δ μ+2(δ^2)(μ^2))/2+2(μ^2)(α β+δ μ)(Subscript[c, k])-β(2μ-1)(α β+2δ μ)(Subscript[u, k])+2β δ (μ^2)(Subscript[c, k])(Subscript[u, k])-(β^2)δ(3μ-1)(Subscript[u, k]^2)/2+α(α β+2 δ μ)(Subscript[w, k])+2α δ (μ^2)(Subscript[c, k])(Subscript[w, k])-2(t-1)(δ^2)(α β+δ μ)(Subscript[u, k])(Subscript[w, k])+2(δ^2)(μ^2)(Subscript[c, k])(Subscript[u, k])(Subscript[w, k])-β (δ^2)(2μ-1)(Subscript[u, k]^2)(Subscript[w, k])+(α^2)δ(1+μ)(Subscript[w, k]^2)/2+α (δ^2)(Subscript[u, k])(Subscript[w, k]^2)-(t-1)(δ^4)(Subscript[u, k]^2)(Subscript[w, k]^2)/2;
(Subscript[R, i_,j_]^(+)):=𝔼[1,(Subscript[b, i])(Subscript[c, j]),(Subscript[u, i])(Subscript[w, j]),-(Subscript[c, i])(((t-1))^2)/2-(Subscript[c, i]^2)(((t-1))^2)/2+(Subscript[c, i])(Subscript[c, j])((t^2)-t-2)/2-(Subscript[c, j])(Subscript[u, i])(Subscript[w, i])/2+(Subscript[c, i])(1-t)(Subscript[u, i])(Subscript[w, i])-(Subscript[u, i]^2)(Subscript[w, i]^2)/2+(Subscript[u, i])(Subscript[w, j])+(Subscript[c, j])t (Subscript[u, i])(Subscript[w, j])/2+(Subscript[c, i])(t-2)t (Subscript[u, i])(Subscript[w, j])+(Subscript[c, i])(1+t)(Subscript[u, j])(Subscript[w, j])/2+(t-1)(Subscript[u, i]^2)(Subscript[w, i])(Subscript[w, j])-(t-2)t (Subscript[u, i]^2)(Subscript[w, j]^2)/2];
(Subscript[R, i_,j_]^(-)):=𝔼[1,-(Subscript[b, i])(Subscript[c, j]),-(t^(-1))(Subscript[u, i])(Subscript[w, j]),(Subscript[c, i])(((t-1))^2)/2+(Subscript[c, i]^2)(((t-1))^2)/2+(Subscript[c, i])(Subscript[c, j])(2+t-(t^2))/2+(Subscript[c, j])(Subscript[u, i])(Subscript[w, i])/2+(Subscript[c, i])(t-1)(Subscript[u, i])(Subscript[w, i])+(Subscript[u, i]^2)(Subscript[w, i]^2)/2+(1-(t^(-1)))(Subscript[u, i])(Subscript[w, j])/2+(Subscript[c, i])(2t-5+3(t^(-1)))(Subscript[u, i])(Subscript[w, j])/2+(Subscript[c, j])((t^(-1))+1-t)(Subscript[u, i])(Subscript[w, j])/2-(Subscript[c, i])(t+1)(Subscript[u, j])(Subscript[w, j])/2+(2-3(t^(-1)))(Subscript[u, i]^2)(Subscript[w, i])(Subscript[w, j])/2+(1+2(t^(-2))-3(t^(-1)))(Subscript[u, i]^2)(Subscript[w, j]^2)/2-(t^(-1))(1+t)(Subscript[u, i])(Subscript[u, j])(Subscript[w, j]^2)/2];
(Subscript[ur, i_]):=𝔼[(t^(-1/4)),0,0,(Subscript[c, i])t/4+(Subscript[u, i])(Subscript[w, i])/8];
(Subscript[nr, i_]):=𝔼[(t^(1/4)),0,0,-(Subscript[c, i])(t^3)/4-(t^2)(Subscript[u, i])(Subscript[w, i])/8];
(Subscript[ul, i_]):=𝔼[(t^(1/4)),0,0,(Subscript[c, i])t(4+t)/4-(t^2)(Subscript[u, i])(Subscript[w, i])/8];
(Subscript[nl, i_]):=𝔼[(t^(-1/4)),0,0,-(Subscript[c, i])(1+4(t^(-1)))/4+(Subscript[u, i])(Subscript[w, i])/8];

z=(Subscript[R, 1,14]^(+))(Subscript[R, 5,2]^(-))(Subscript[nr, 3])(Subscript[ul, 4])(Subscript[R, 19,6]^(+))(Subscript[R, 7,10]^(-))(Subscript[nl, 8])(Subscript[ur, 9])(Subscript[R, 11,20]^(+))(Subscript[nr, 12])(Subscript[ul, 13])(Subscript[R, 15,18]^(-))(Subscript[nl, 16])(Subscript[ur, 17]);
(Do[z=z//(Subscript[m, 1,k->1]), {k,2,20}]; z=z /. (Subscript[a_, 1]):>a)

Exporting the above as PDF files

The below is adapted from pensieve://2016-04/GaussGassner/GaussGassnerDemo.nb.

ConditionalExport[fname_String, rest___] := Module[{temp, exists},
temp="ConditionalExportTemporary"<>"."<>FileExtension[fname];
exists=FileExistsQ[fname];
Export[temp, rest];
If[exists && FileByteCount[fname]===FileByteCount[temp],
DeleteFile[temp],
(* else *) Print["Exporting "<>fname<>"..."];
If[exists, DeleteFile[fname]];
RenameFile[temp, fname]
];
fname
]

SetOptions[$FrontEndSession,PrintingStyleEnvironment->"Working"];
TagProperties[_] := {};
TagProperties["ct-def"] = {PageWidth ->5/0.66};
Options[CellExport] = {
PageWidth -> 3.2/0.66*4.2/3.8, CellFilter -> Identity, ExportDirectory -> "Snips", ExportBaseFilename -> Automatic, ExportFormat -> ".pdf", ExportOptions -> {}, Split -> False
};
CellExport[tag_String, opts___Rule] := CellExport[
NotebookGet[EvaluationNotebook[]],
tag, opts
];
CellExport[nb_Notebook, tag_String] := CellExport[nb, tag, TagProperties[tag]];
CellExport[nb_Notebook, tag_String, OptionsPattern[]] := Module[
{cells, cell, filename, format},
filename = FileNameJoin[{
OptionValue[ExportDirectory] /. Automatic -> Directory[],
OptionValue[ExportBaseFilename] /. Automatic -> tag
}];
format=OptionValue[ExportFormat];
cells=OptionValue[CellFilter][Cases[
nb, c_Cell /; FreeQ[List@@c, Cell] && !FreeQ[c, CellTags->tag],
Infinity
]];
If[!OptionValue[Split],
If[Length[cells]≥1,
If[Length[cells]==1,
cells=Join[First[cells], Cell[PageWidth ->1.2 72OptionValue[PageWidth], Background->{White, Opacity[0]}]],
cells=Cell[CellGroup[cells], PageWidth -> 72OptionValue[PageWidth]]
];
ConditionalExport[
filename<>format,cells,
ImageResolution -> 300,
OptionValue[ExportOptions]
]
],
k=0;
Table[
++k;
ConditionalExport[
filename<>"-"<>ToString[k]<>format,
Append[cell, PageWidth -> 72OptionValue[PageWidth]],
ImageResolution -> 300,
OptionValue[ExportOptions]
],
{cell, cells}
]
]
];

ExportCells:=(
nb=NotebookGet[EvaluationNotebook[]];
tags=Cases[nb, (CellTags->tag_String) :> tag, Infinity ] // Union;
Print[tags];
CellExport /@ tags;
Print["Done."]
);

ExportCells