βSimp=Factor; SetAttributes[βCollect, Listable];
βCollect[B[ω_, Λ_]] := B[βSimp[ω],
Collect[Λ, (Subscript[h, _]), Collect[#,(Subscript[t, _]), βSimp]&]];
βForm[B[ω_, Λ_]] := Module[{ts, hs, M},
ts = Union[Cases[B[ω, Λ], (Subscript[(t|T), s_]) :> s, Infinity]];
hs = Union[Cases[B[ω, Λ], (Subscript[h, s_]) :> s, Infinity]];
M = Outer[βSimp[Coefficient[Λ, (Subscript[h, #1]) (Subscript[t, #2])]]&, hs, ts];
PrependTo[M, (Subscript[t, #])& /@ ts];
M = Prepend[Transpose[M], Prepend[(Subscript[h, #])& /@ hs, ω]];
MatrixForm[M]];
βForm[else_] := else /. β_B :> βForm[β];
Format[β_B, StandardForm] := βForm[β];
B /: B[ω1_, β1_] == B[ω2_, β2_] := (ω1 == ω2) && (β1 == β2);

⟨μ_⟩ := μ /. (Subscript[t, _])->1;
(Subscript[tm, x_,y_->z_])[β_] := β /. {(Subscript[t, x|y])->(Subscript[t, z]), (Subscript[T, x|y])->(Subscript[T, z])};
(Subscript[hm, x_,y_->z_])[B[ω_, Λ_]] := Module[
{α= D[Λ, (Subscript[h, x])], β=D[Λ, (Subscript[h, y])], γ=Λ /. (Subscript[h, x|y]) -> 0},
B[ω, (α+(1+⟨α⟩)β)(Subscript[h, z])+γ] // βCollect];
(Subscript[sw, x_,y_])[B[ω_, Λ_]] := Module[{α,β,γ,δ,ϵ},
α = Coefficient[Λ, (Subscript[h, y])(Subscript[t, x])]; β = D[Λ, (Subscript[t, x])] /. (Subscript[h, y]) -> 0;
γ = D[Λ, (Subscript[h, y])] /. (Subscript[t, x]) -> 0;      δ = Λ /. (Subscript[h, y])|(Subscript[t, x]) -> 0;
ϵ = 1+α;
B[ω*ϵ, α(1+⟨γ⟩/ϵ)(Subscript[h, y])(Subscript[t, x]) + β(1+⟨γ⟩/ϵ)(Subscript[t, x])
      +γ/ϵ (Subscript[h, y])                          + δ-γ*β/ϵ
] // βCollect];
(Subscript[gm, x_,y_->z_])[β_] := β // (Subscript[sw, x,y]) // (Subscript[hm, x,y->z]) // (Subscript[tm, x,y->z]);
(Subscript[tΔ, x_->y_,z_])[β_]:=β/.{(Subscript[t, x])->(Subscript[t, y])+(Subscript[t, z]),(Subscript[T, x])->(Subscript[T, y])(Subscript[T, z])};
(Subscript[hΔ, x_->y_,z_])[β_]:=β/.{(Subscript[h, x])->(Subscript[h, y])+(Subscript[h, z])};
B /: B[ω1_, Λ1_]B[ω2_, Λ2_] := B[ω1*ω2, Λ1+Λ2];
(Subscript[Rp, x_,y_]) := B[1, ((Subscript[T, x])-1)(Subscript[t, x])(Subscript[h, y])];
(Subscript[Rm, x_,y_]) := B[1, ((Subscript[T, x]^(-1))-1)(Subscript[t, x])(Subscript[h, y])];

Demo

{β= B[ω,Sum[(Subscript[α, 10i+j])(Subscript[t, i])(Subscript[h, j]), {i,{1,2,3}}, {j,{4,5}}]],
β1=β // (Subscript[tm, 1,2->1]) // (Subscript[sw, 1,4]);
β2 =β// (Subscript[sw, 2,4]) // (Subscript[sw, 1,4]) //  (Subscript[tm, 1,2->1]),
FullSimplify[β1]==FullSimplify[β2]
}

{β=B[ω,a (Subscript[t, 1])(Subscript[h, 1])+b (Subscript[t, 1])(Subscript[h, 2])],
β//(Subscript[hm, 1,2->1])//(Subscript[tΔ, 1->1,2]),
β//(Subscript[tΔ, 1->1,2])//(Subscript[hm, 1,2->1])
}

(Subscript[Rp, 1,4])(Subscript[Rm, 2,3])//(Subscript[gm, 1,2->1])//(Subscript[gm, 3,4->3])

{(Subscript[Rm, 5,1])(Subscript[Rm, 6,2])(Subscript[Rp, 3,4])//(Subscript[gm, 1,4->1])//(Subscript[gm, 2,5->2])//(Subscript[gm, 3,6->3]),
 (Subscript[Rp, 6,1])(Subscript[Rm, 2,4])(Subscript[Rm, 3,5])//(Subscript[gm, 1,4->1])//(Subscript[gm, 2,5->2])//(Subscript[gm, 3,6->3])}

β=(Subscript[Rm, 12,1])(Subscript[Rm, 2,7])(Subscript[Rm, 8,3])(Subscript[Rm, 4,11])(Subscript[Rp, 16,5])(Subscript[Rp, 6,13])(Subscript[Rp, 14,9])(Subscript[Rp, 10,15])

Do[β = β // (Subscript[gm, 1,k->1]), {k,2,10}]; β

Do[β = β // (Subscript[gm, 1,k->1]), {k,11,16}]; β

<< KnotTheory`
Alexander[Knot[8,17]][(Subscript[T, 1])] // Factor