Pensieve header: A $V\times F$ formula for the Alexander polynomial following Kauffman’s Formal Knot Theory, written by DBN in February 2024. Almost exactly matches with the Martchenkov program.

<< KnotTheory`

K=Knot[3,1]

n=Length[pd=List@@PD[K]]

pd

XingsByArmpits=pd/.x:X[i_,j_,k_,l_]:>If[PositiveQ[x],(SubPlus[X])[-i,j,k,-l],(SubMinus[X])[-j,k,l,-i]]

bends=Times@@XingsByArmpits/._[X][a_,b_,c_,d_]:>(Subscript[p, a,-d])(Subscript[p, b,-a])(Subscript[p, c,-b])(Subscript[p, d,-c])

faces=bends//.(Subscript[p, x__,y_])(Subscript[p, y_,z__]):>(Subscript[p, x,y,z])

M=SparseArray[Flatten@Table[
x=XingsByArmpits[[i]];
js=Position[faces,#][[1,1]]& /@ List@@x;
If[Head[x]===(SubPlus[X]),s=1,s=-1];
{{i,js[[1]]}->(T^(-s)), {i,js[[2]]}->1, {i,js[[3]]}->(T^s),{i,js[[4]]}->1},
{i,n}], {n,n+2}]

Normal[M]

Det[Delete[{Position[faces,#][[1,1]]}& /@ {1,-1}]/@Normal[M]]/.T->(T^(1/2))

A[K_]:=Module[{pd,n,XingsByArmpits,bends,faces,M,x,js,i},
n=Length[pd=List@@PD[K]];
XingsByArmpits=pd/.x:X[i_,j_,k_,l_]:>If[PositiveQ[x],(SubPlus[X])[-i,j,k,-l],(SubMinus[X])[-j,k,l,-i]];
bends=Times@@XingsByArmpits/._[X][a_,b_,c_,d_]:>(Subscript[p, a,-d])(Subscript[p, b,-a])(Subscript[p, c,-b])(Subscript[p, d,-c]);
faces=bends//.(Subscript[p, x__,y_])(Subscript[p, y_,z__]):>(Subscript[p, x,y,z]);
M=SparseArray[Flatten@Table[
x=XingsByArmpits[[i]];
js=Position[faces,#][[1,1]]& /@ List@@x;
If[Head[x]===(SubPlus[X]),s=1,s=-1];
{{i,js[[1]]}->(T^(-s)), {i,js[[2]]}->1, {i,js[[3]]}->(T^s),{i,js[[4]]}->1},
{i,n}], {n,n+2}];
Expand[Det[Delete[{Position[faces,#][[1,1]]}& /@ {1,-1}]/@Normal[M]]
]/.T->(T^(1/2))
]

A/@AllKnots[{3,7}]

Table[Factor[((A[K])/(Alexander[K][T]))],{K, AllKnots[{3,10}]}]