Id=Cycles[{{}}];
(Subscript[σ, i_,j_]):=Cycles[{{i,j}}];
ht[σ_Cycles]=0;
δ[σ_Cycles]=0;
(Subscript[c, k_])[Cycles[l_List]]:=Cycles[k+l];

W[lft___,W[mid___],rgt___]:=W[lft,mid,rgt];
W[lft___,0,rgt___]=0;
W[lft___,s_Plus,rgt___]:=W[lft,#,rgt]&/@s;
W[lft___,c_?NumberQ * U_,rgt___]:=c W[lft,U,rgt];
W[lft___,Cycles@{},rgt___]:=W[lft,rgt];
W[lft___,p1_Cycles,p2_Cycles,rgt___] := W[lft,p1\[PermutationProduct]p2,rgt];
(Subscript[c, k_])[w_W]:=(Subscript[c, k])/@w;

(Subscript[c, k_])[0]=0;
(Subscript[c, k_])[s_Plus]:=(Subscript[c, k])/@s;
(Subscript[c, k_])[a_*w_W]:=a (Subscript[c, k])[w];
(Subscript[c, k_])[(Subscript[U_, j_])]:= (Subscript[U, k+j]);

σ[(Subscript[U_, k_])]:=(Subscript[c, k])[σ[U]];
σ[W[]]=Id;
σ[p_Cycles]:=p;
σ[W[f_,r___]] := σ[f]\[PermutationProduct]σ[W[r]];

δ[0]=0;
δ[s_Plus]:=δ/@s;
δ[c_*w_W]:=c δ[w];
δ[W[]]=0;
δ[(Subscript[U_, k_])]:=(Subscript[c, k])[δ[U]];
δ[W[f_,r___]]:=W[δ[f],r]+(((-1))^(ht[f]))W[f,δ[W[r]]];

W[(Subscript[σ, 1,2]),(Subscript[σ, 1,2])+(Subscript[σ, 1,3])-(Subscript[σ, 3,4])]

ht[(Subscript[U_, k_])]:=ht[U];

sfil[H]=1; vdeg[H]=1; ht[H]=0; δ[H]=0; σ[H]=Id;

sfil[R[1]]=2; vdeg[R[1]]=1; ht[R[1]]=1; δ[R[1]]:=W[(Subscript[σ, 1,2]),(Subscript[H, 0])+(Subscript[H, 1])]-W[(Subscript[H, 0])+(Subscript[H, 1]),(Subscript[σ, 1,2])]; σ[R[1]]=(Subscript[σ, 1,2]);

(Subscript[𝒰, s_,d_,h_])[___] /; (d<0∨h<0 ):= {};
(Subscript[𝒰, s_,0,0])[___]:=W/@GroupElements@SymmetricGroup@s;
(Subscript[𝒰, s_,d_,h_])[gens___]:=Flatten[Table[
Table[W[σ,(Subscript[U, k]),w],{w,(Subscript[𝒰, s,d-vdeg[U],h-ht[U]])[gens]},{k,0,s-sfil[U]}],
{σ,GroupElements@SymmetricGroup@s},{U,{gens}}
]];
(Subscript[𝒰, p_Cycles,s_,d_,h_])[gens___]:=Select[(Subscript[𝒰, s,d,h])[gens],σ[#]==p&];

(Subscript[ρ, p_,s_,d_,h_])[gens___]:=Module[
{b0=(Subscript[𝒰, p,s,d,h-1])[gens],b1=(Subscript[𝒰, p,s,d,h])[gens],δx},
If[b0==={}∨b1==={},0,
MatrixRank[Table[δx=δ[x]; Table[Coefficient[δx,y],{y,b0}], {x,b1}]]
]];
(Subscript[β, p_,s_,d_,h_])[gens___]:=Length[(Subscript[𝒰, p,s,d,h])[gens]]-(Subscript[ρ, p,s,d,h])[gens]-(Subscript[ρ, p,s,d,h+1])[gens]

(Subscript[ρ, Id,2,2,1])[H,R[1]]

σ/@(Subscript[𝒰, 2,2,0])[H,R[1]]

(Subscript[β, Id,4,1,0])[H,R[1]] // Timing

(Subscript[β, Id,3,1,1])[H,R[1]] // Timing