Computing the Jones Polynomial

The function JP[ ] returns the Jones polynomial of a knot - an embedding of (S^1) in 3 dimensional Euclidean space defined up to ambient isotopies - while also printing its Kauffman bracket and writhe. The computation of the Kauffman bracket works as the one made in class. For the computation of the writhe to work, the expression of the form X[(Subscript[i, 1]),(Subscript[j, 1]),(Subscript[k, 1]),(Subscript[l, 1])]... X[(Subscript[i, n]),(Subscript[j, n]),(Subscript[k, n]),(Subscript[l, n])] representing the knot must be chosen in a systematic way (more so than what is necessary to compute the Kauffman bracket). The method for entering a knot K is as follows :

Choose an orientation on K

Number the edges of K separated by crossings consecutively following the positive orientation, until coming back to edge 1. Doing so, choose edge 1 so that, at the first crossing encountered in the positive direction along K, the thread going from edge 1 to edge 2 passes ‘under’ the other thread.

For each crossing X in K, multiply the expression for K by the factor X[i,j,k,l], where i is the label of the edge incoming to the crossing on the thread going ‘under’. j,k,l are the numbers of the other edges, in the order given by counterclockwise rotation starting from the edge i. That is, X[i,j,k,l] is associated to the crossing drawn below. This process yields the final expression for K.

Note that the function JP cannot compute the Jones polynomial of the simple unknot (i.e. of a circle without crossings). I suppose it would be easy to deal with this case, but obviously it’s not worth the effort... No need of an exoskeleton to compute that.

<<KnotTheory`

Rule[a,b]

JP[K, Verbose->True]

Clear[JP]

SetAttributes[P,Orderless];
JP[K_Times,opts___Rule]:=Module[{verb,b1,b2,b3,b4,b5,w,J},
verb=Verbose/.{opts} /. Verbose ->False;
b1=K//.X[i_,j_,k_,l_]:>A P[i,j] P[k,l]+B P[j,k] P[i,l];
b2=Expand[b1];
b3=b2//.P[i_,j_] P[j_,k_]:>P[i,k];
b4=b3//.{((P[i_,j_])^2)->d,P[i_,i_]->d};
b5=Expand[b4//.{B->1/A,d->-(A^2)-1/(A^2)}];
If[verb, Print["The Kauffman bracket is "]];
If[verb, Print[b5]];
w=K/.{Times->Plus, X[_,1,_,_] ->1, X[_,_,_,1]->-1, X[_,j_,_,l_]:>If[j>l,1,-1]};
If[verb,Print["The writhe is "]];
If[verb,Print[w]];
If[verb,Print["The Jones Polynomial is "]];
J=Expand[(((-(A^3)))^(-w))b5]
];
JP[K_PD, opts___] := JP[Times@@K, opts]

Examples

Trefoil Knot

Ktre1=X[1,5,2,4]X[3,1,4,6]X[5,3,6,2];

JP[Ktre1]

JP[PD[Knot[3,1]]]

JP[Ktre1, Verbose -> True]

Mirror Trefoil Knot

;

Ktre2=X[1,4,2,5]X[3,6,4,1]X[5,2,6,3];

JP[Ktre2]

JP[PD[Knot[3,1]]]

Knot (Subscript[8, 17])

;

K817=X[1,12,2,13]X[3,8,4,9]X[5,1,6,16]X[7,2,8,3]X[9,15,10,14]X[11,4,12,5]X[13,7,14,6]X[15,11,16,10];

JP[K817]

PD[Knot[8,17]]

JP[PD[Knot[8,17]]]

AllKnots[{3,11}] // Length

Timing[tab=Table[JP[PD[K]], {K, AllKnots[{3,11}]}];]

Union[tab]//Length