A new slide.

Pensieve header: November 3: quintic talk slides.

Today. Nobody solves the quintic, then non-commutative Gaussian elimination (NCGE), then (unlikely) EIWL-10-12, then even less likely, Patterns.

Topics (in no particular order). Whatever you may suggest; whatever comes to my mind; the Fibonacci numbers; the Catalan numbers; the Jones polynomial; a more efficient Jones algorithm; a riddle on spheres; Khovanov homology; Γ-calculus; the Hopf fibration; Hilbert’s 13th problem; non-commutative Gaussian elimination; free Lie algebras; the Baker-Campbell-Hausdorff formula; wacky numbers; an order 4 torus; the Schwarz Lantern; knot colourings; the Temperley-Lieb pairing; the dodecahedral link; sound experiments; barycentric subdivisions; some Peano curves; braid closures and Vogel’s algorithm; the insolubility of the quintic; phase portraits; the Mandelbrot set; shadows of the Cantor aerogel; quilt plots; some image transformations; De Bruijn graphs; the Riemann series theorem; finite type invariants and the Willerton fish; the Towers of Hanoi; Hochschild homology of (some) coalgebras; convolutions and image improvements.

An Image Manipulation Challenge

The image at http://drorbn.net/bbs/show?shot=17-1750-171016-111042.jpg is pathetic. Can you improve it? Whatever you do, should also work well with all other images at http://drorbn.net/bbs/show.php?prefix=17-1750.

A Graphics Challenge

The torus (S^1)×(S^1) has an order 4 symmetry. Can you draw it in such a manner that it will manifest?

The Cow Problem (Leonard)

A farmer has 19 cows, and she wishes to give them to her daughters to that the first will get 1/2, the second 1/4, and the third 1/5. This is obviously impossible. A wise woman hears of the problem and suggests: “I’ll add on one of my cows, so you’ll have 20. The first daughter will get 10, the second 5, the third 4, I’ll take back the remaining cow, and everyone is happy!”.

Problem. Are there any other quadruples like (19,2,4,5), for which the same trick will work? What are all of them?

Hint. It is sometimes better to analyze and generalize, first.

Reminders

We do have class meetings next week!

Mathematica receipts due Monday November 6, in class.

Submissions are limited to 20Mb.

Dror Bar - Natan: Talks: Sydney-1708:

Nobody Solves the Quintic

Umniversity of Sydney Undergraduate Lecture, August 2017

Abstract. Everybody knows that nobody can solve the quintic. Indeed this insolubility is a well known hard theorem, the high point of a full-semester course on Galois theory, often taken in one’s 3rd or 4th year of university mathematics. I’m not sure why so few know that the same theorem can be proven in about 15 minutes using *very* basic and easily understandable topology, accessible to practically anyone.

SetDirectory["C:\\drorbn\\AcademicPensieve\\Talks\\Sydney-1708"];
PRoot[name_, a_, n_] := PRoot[name, n] = If[NumberQ[PRoot[name, n]],
MinimalBy[
N[(a^(1/n))]Table[(E^(2π I k/n)), {k,n}],
Abs[#-PRoot[name,n]]&
][[1]],
(a^(1/n))
];
InputBackground=Graphics[{
Pink, Disk[],
Red, Point[{0,0}],
Table[{Line[{{t,-1},{t,1}}], Line[{{-1,t},{1,t}}]}, {t,-1,1,2/3}]
}];
OutputBackground = {
LightBlue, Disk[],
Blue, Point[{0,0}],
Table[{Line[{{t,-1},{t,1}}], Line[{{-1,t},{1,t}}]}, {t,-1,1,2/3}],
Black
};
Pt@c_ := {Re[c],Im[c]};

Go;

Handout

Import["../../Talks/Sydney-1708/Quintic-Handout_800.png"]

Definitions and Very Simple Examples

Definition. The commutator of two operations A and B is [A,B] := (ABA^(-1))(B^(-1)), or “do A, do B, undo A, undo B”.

Example 0. In ℤ, [m,n] = 0.

+2017+729-2017-729

Example 1. In (Subscript[S, 3]), [(12), (23)] = (12) (23) (((12))^(-1))(((23))^(-1))=(123) and in general in (Subscript[S, ≥3]), [(ij),(jk)]=(ijk).

Example 2. In (Subscript[S, ≥4]), [(ijk), (jkl)] = (ijk) (jkl) (((ijk))^(-1))(((jkl))^(-1))=(il)(jk).

Example 3. In (Subscript[S, ≥5]), [(ijk), (klm)] = (ijk) (klm) (((ijk))^(-1))(((klm))^(-1))=(jkm).

Example 4. So, in fact, in (Subscript[S, 5]), (123) = [(412),(253)] = [[(341),(152)],[(125),(543)]]
= [[[(234),(451)],[(315),(542)]],[[(312),(245)],[(154),(423)]]]
= [
  [[[(123),(354)],[(245),(531)]],[[(231),(145)],[(154),(432)]]],
  [[[(431),(152)],[(124),(435)]],[[(215),(534)],[(142),(253)]]]
].

Decommute = p[j_,k_,m_] :>  Module[{i,l},
{i,l}=Complement[Range[5],{j,k,m}];
c[p[i,j,k],p[k,l,m]]
];
Format[p[i_,j_,k_]] := "("<>ToString[i]<>ToString[j]<>ToString[k]<>")";
Format[c[a_,b_]] := "["<>ToString[a]<>","<>ToString[b]<>"]";

p[2,3,5]

p[2,3,5] /. Decommute

p[1,2,3] /. Decommute

p[1,2,3] /. Decommute /. Decommute

p[1,2,3] /. Decommute /. Decommute /. Decommute

p[1,2,3] /. Decommute /. Decommute /. Decommute /. Decommute

The Quintic

(ax^5)+(bx^4)+(cx^3)+(dx^2)+ex+f=0

Can you solve the quintic in radicals? Is there a formula for the zeros of a degree 5 polynomial in terms of its coefficients, using only the operations on a scientific calculator?  (+,-,×,÷,(a^(1/n)))

History: First solved by Abel / Galois in the 1800s. Our solution follows Arnold’s topological solution from the 1960s. I could not find the original writeup by Arnold (if it at all exists), yet see:

V.B. Alekseev, Abel’s Theorem in Problems and Solutions, Based on the Lecture of Professor V.I. Arnold, Kluwer 2004.

A. Khovanskii, Topological Galois Theory, Solvability and Unsolvability of Equations in Finite Terms, Springer 2014.

B. Katz, Short Proof of Abel’s Theorem that 5th Degree Polynomial Equations Cannot be Solved, YouTube video, http://youtu.be/RhpVSV6iCko.

Solving the Quadratic (ax^2)+bx+c=0

Δ=(b^2)-4a c;
δ=(Sqrt[Δ]);
r=(-b+δ)/(2a)

Module[{a0,b0,c0,a,b,c,Δ,δ,r},
{a0,b0,c0}={{1,0},{0,0},{0,1/3}};
GraphicsGrid[Partition[#,2]& @{
LocatorPane[Dynamic[{a0,b0,c0}],InputBackground, Appearance -> {"a", "b", "c"}],
Dynamic[Graphics[{OutputBackground,
a={1,I}.a0; b={1,I}.b0; c={1,I}.c0;
Δ=(b^2)-4 a c;
Text["Δ",{Re[Δ], Im[Δ]}]
}, PlotRange->All, PlotLabel -> "Δ=(b^2)-4ac"]],
Dynamic[Graphics[{OutputBackground,
δ=PRoot["Δ[2]", Δ,2];
Text["δ", {Re[δ], Im[δ]}]
}, PlotRange->All, PlotLabel -> "δ=(Sqrt[Δ])"]],
Dynamic[Graphics[{OutputBackground,
r=(-b+δ)/(2a);
Point[{Re[r], Im[r]}]
}, PlotRange->All, PlotLabel -> "r=(-b+δ)/(2a)"]]
}]
]

Testing the Quadratic Solution

Module[{λ1,λ2,x,a,b,c,Δ,δ,r},
{λ1,λ2}={{1,1}/2, {1,-1}/2};
GraphicsGrid[Partition[#,3]& @ {
LocatorPane[Dynamic[{λ1,λ2}],InputBackground, Appearance -> {"(Subscript[λ, 1])", "(Subscript[λ, 2])"}],
Dynamic[Graphics[{OutputBackground,
{c,b,a}=CoefficientList[(x-{1,I}.λ1)(x-{1,I}.λ2), x];
Text["a", {Re[a],Im[a]}], Text["b", {Re[b],Im[b]}], Text["c",{Re[c],Im[c]}]
}, PlotRange->All, PlotLabel -> "(x-(Subscript[λ, 1]))(x-(Subscript[λ, 2]))=(ax^2)+bx+c"]],
Dynamic[Graphics[{OutputBackground,
Δ=(b^2)-4 a c;
Text["Δ",{Re[Δ], Im[Δ]}]
}, PlotRange->All, PlotLabel -> "Δ=(b^2)-4ac"]],
Dynamic[Graphics[{OutputBackground,
δ=PRoot["Δ[2]", Δ,2];
Text["δ", {Re[δ], Im[δ]}]
}, PlotRange->All, PlotLabel -> "δ=(Sqrt[Δ])"]],
Dynamic[Graphics[{OutputBackground,
r=(-b+δ)/(2a);
Point[{Re[r], Im[r]}]
}, PlotRange->All, PlotLabel -> "r=(-b+δ)/(2a)"]],
Null
}]
]

Square Roots and Persistent Square Roots

b1={{1,0}};
GraphicsGrid[{{LocatorPane[Dynamic[b1],InputBackground], 
Dynamic[Graphics[{OutputBackground, Point[r=((b1[[1,1]]+I b1[[1,2]])^(1/2)); {Re[r], Im[r]}]}, PlotRange->All, PlotLabel -> "A Square Root"]],Dynamic[Graphics[{OutputBackground, Point[r=PRoot["ex",b1[[1,1]]+I b1[[1,2]],2]; {Re[r], Im[r]}]}, PlotRange->All, PlotLabel -> "A Persistent Square Root"]]
}}]

Leading Questions

“Yes, Prime Minister”, 1986.

Sir Humphrey: You know what happens: nice young lady comes up to you. Obviously you want to create a good impression, you don’t want to look a fool, do you? So she starts asking you some questions: Mr. Woolley, are you worried about the number of young people without jobs?
Bernard Woolley: Yes
Sir Humphrey: Are you worried about the rise in crime among teenagers?
Bernard Woolley: Yes
Sir Humphrey: Do you think there is a lack of discipline in our Comprehensive schools?
Bernard Woolley: Yes
Sir Humphrey: Do you think young people welcome some authority and leadership in their lives?
Bernard Woolley: Yes
Sir Humphrey: Do you think they respond to a challenge?
Bernard Woolley: Yes
Sir Humphrey: Would you be in favour of reintroducing National Service?
Bernard Woolley: Oh...well, I suppose I might be.
Sir Humphrey: Yes or no?
Bernard Woolley: Yes
Sir Humphrey: Of course you would, Bernard. After all you told me can’t say no to that. So they don’t mention the first five questions and they publish the last one.
Bernard Woolley: Is that really what they do?
Sir Humphrey: Well, not the reputable ones no, but there aren’t many of those. So alternatively the young lady can get the opposite result.
Bernard Woolley: How?
Sir Humphrey: Mr. Woolley, are you worried about the danger of war?
Bernard Woolley: Yes
Sir Humphrey: Are you worried about the growth of armaments?
Bernard Woolley: Yes
Sir Humphrey: Do you think there is a danger in giving young people guns and teaching them how to kill?
Bernard Woolley: Yes
Sir Humphrey: Do you think it is wrong to force people to take up arms against their will?
Bernard Woolley: Yes
Sir Humphrey: Would you oppose the reintroduction of National Service?
Bernard Woolley: Yes
Sir Humphrey: There you are, you see Bernard. The perfect balanced sample.

Button["Tristan", Print[1+1]]

Button["Play", SystemOpen["../../2015-01/Commutators/LeadingQuestions.mp4"]]

Solving the Cubic (ax^3)+(bx^2)+cx+d=0

Δ= -18a b c d+4(b^3)d-(b^2)(c^2)+4a (c^3)+27(a^2)(d^2);
δ=(Sqrt[Δ]);
Γ= 2(b^3)-9a b c+27(a^2)d+3(Sqrt[3])a δ;
γ=((Γ/2)^(1/3));
r=-(b+γ+((b^2)-3a c)/γ)/(3a)

Module[{a0,b0,c0,d0,a,b,c,d,x,Δ,δ,Γ,γ,r},
{a0,b0,c0,d0}={{0,-1/3},{0,0},{1/3,0},{-1/3,0}};
GraphicsGrid[Partition[#,3]& @ {
LocatorPane[Dynamic[{a0,b0,c0,d0}],InputBackground,Appearance -> {"a", "b", "c", "d","e"}],
Dynamic[Graphics[{OutputBackground,
a={1,I}.a0; b={1,I}.b0; c={1,I}.c0; d={1,I}.d0;
Δ= -18a b c d+4(b^3)d-(b^2)(c^2)+4a (c^3)+27(a^2)(d^2);
Text["Δ", {Re[Δ],Im[Δ]}]
}, PlotRange->All, PlotLabel ->"Δ"]],
Dynamic[Graphics[{OutputBackground,
δ=PRoot["3Δ",Δ,2];
Text["δ", {Re[δ],Im[δ]}]
}, PlotRange->All, PlotLabel ->"δ=(Sqrt[Δ])"]],
Dynamic[Graphics[{OutputBackground,
Γ= 2(b^3)-9a b c+27(a^2)d+3(Sqrt[3])a δ;
Text["Γ", {Re[Γ],Im[Γ]}]
}, PlotRange->All, PlotLabel -> "Γ"]],
Dynamic[Graphics[{OutputBackground,
γ=PRoot["Γ",Γ/2,3];
Text["γ", {Re[γ],Im[γ]}]
}, PlotRange->All, PlotLabel -> "γ=((Γ/2)^(1/3))"]],
Dynamic[Graphics[{OutputBackground,
r=-(b+γ+((b^2)-3a c)/γ)/(3a);
Text["r", {Re[r], Im[r]}]
}, PlotRange->All, PlotLabel->"r"]],
Null,Null
}]
]

Testing the Cubic Solution

Module[{λ1,λ2,λ3,a,b,c,d,x,Δ,δ,Γ,γ,r},
{λ1,λ2,λ3}=(1/2){{1,1}, {1,-1}, {-1,1}};
GraphicsGrid[Partition[#,3]& @ {
LocatorPane[Dynamic[{λ1,λ2,λ3}],InputBackground,Appearance -> {"(Subscript[λ, 1])", "(Subscript[λ, 2])", "(Subscript[λ, 3])"}],
Dynamic[Graphics[{OutputBackground,
{d,c,b,a}=CoefficientList[(x-{1,I}.λ1)(x-{1,I}.λ2)(x-{1,I}.λ3), x];
Text["a", {Re[a],Im[a]}], Text["b", {Re[b],Im[b]}], Text["c",{Re[c],Im[c]}],Text["d",{Re[d],Im[d]}]
}, PlotRange->All, PlotLabel -> "a,b,c,d"]],
Dynamic[Graphics[{OutputBackground,
Δ= -18a b c d+4(b^3)d-(b^2)(c^2)+4a (c^3)+27(a^2)(d^2);
Text["Δ", {Re[Δ],Im[Δ]}]
}, PlotRange->All, PlotLabel ->"Δ"]],
Dynamic[Graphics[{OutputBackground,
δ=PRoot["3Δ",Δ,2];
Text["δ", {Re[δ],Im[δ]}]
}, PlotRange->All, PlotLabel ->"δ=(Sqrt[Δ])"]],
Dynamic[Graphics[{OutputBackground,
Γ= 2(b^3)-9a b c+27(a^2)d+3(Sqrt[3])a δ;
Text["Γ", {Re[Γ],Im[Γ]}]
}, PlotRange->All, PlotLabel -> "Γ"]],
Dynamic[Graphics[{OutputBackground,
γ=PRoot["Γ",Γ/2,3];
Text["γ", {Re[γ],Im[γ]}]
}, PlotRange->All, PlotLabel -> "γ=((Γ/2)^(1/3))"]],
Dynamic[Graphics[{OutputBackground,
r=-(b+γ+((b^2)-3a c)/γ)/(3a);
Text["r", {Re[r], Im[r]}]
}, PlotRange->All, PlotLabel->"r"]],
Null,Null
}]
]

The phenomena observed, that the output r always follows one of the λ’s, is provable.

Note. A swap-dance for (Subscript[λ, 2]) and (Subscript[λ, 3]) becomes a return-dance of a,b,c,d, yet a one-way dance for r.

Solving the Quartic (ax^4)+(bx^3)+(cx^2)+dx+e=0

(Subscript[Δ, 0])=(c^2)-3b d+12a e;
(Subscript[Δ, 1])=2(c^3)-9b c d+27(b^2)e+27a (d^2)-72a c e;
(Subscript[Δ, 2])=(-4((Subscript[Δ, 0])^3)+((Subscript[Δ, 1])^2))/27;
u=(8 a c-3(b^2))/(8(a^2));
v=((b^3)-4a b c+8(a^2)d)/(8(a^3));
(Subscript[δ, 2])=(Sqrt[(Subscript[Δ, 2])]);
Q=((Subscript[Δ, 1])+3(Sqrt[3])(Subscript[δ, 2]))/2;
q=(Q^(1/3));
S=-u/6+(q+(Subscript[Δ, 0])/q)/(12a);
s=(Sqrt[S]);
Γ=-4S-2u-v/s;
γ=(Sqrt[Γ]);
r=-b/(4a)+s+γ/2

Module[{a0,b0,c0,d0,e0,a,b,c,d,e,x,Δ,δ,Q,S,q,s,u,v,Γ,γ,r},
{a0,b0,c0,d0,e0}={{0,-1/3},{0,0},{1/3,0},{-1/3,0},{0,1/3}};
GraphicsGrid[Partition[#,4]& @ {
LocatorPane[Dynamic[{a0,b0,c0,d0,e0}],InputBackground,Appearance -> {"a", "b", "c", "d","e"}],
Dynamic[Graphics[{OutputBackground,
a={1,I}.a0; b={1,I}.b0; c={1,I}.c0; d={1,I}.d0; e={1,I}.e0;
(Subscript[Δ, 0])=(c^2)-3b d+12a e;
(Subscript[Δ, 1])=2(c^3)-9b c d+27(b^2)e+27a (d^2)-72a c e;
(Subscript[Δ, 2])=(-4((Subscript[Δ, 0])^3)+((Subscript[Δ, 1])^2))/27;
u=(8 a c-3(b^2))/(8(a^2));
v=((b^3)-4a b c+8(a^2)d)/(8(a^3));
Text["(Subscript[Δ, 0])", Pt@(Subscript[Δ, 0])], Text["(Subscript[Δ, 1])", Pt@(Subscript[Δ, 1])], Text["(Subscript[Δ, 2])", Pt@(Subscript[Δ, 2])], Text["u", Pt@u], Text["v", Pt@v]
}, PlotRange->All, PlotLabel ->"a,(Subscript[Δ, 0]),(Subscript[Δ, 1]),(Subscript[Δ, 2]),u,v"]],
Dynamic[Graphics[{OutputBackground,
(Subscript[δ, 2])=PRoot["4Δ",(Subscript[Δ, 2]),2];
Text["(Subscript[δ, 2])", Pt@(Subscript[δ, 2])]
}, PlotRange->All, PlotLabel ->"(Subscript[δ, 2])=(Sqrt[(Subscript[Δ, 2])])"]],
Dynamic[Graphics[{OutputBackground,
Q=((Subscript[Δ, 1])+3(Sqrt[3])(Subscript[δ, 2]))/2;
Text["Q", Pt@Q]
}, PlotRange->All, PlotLabel ->"Q"]],
Dynamic[Graphics[{OutputBackground,
q=PRoot["Q",Q,3];
Text["q", Pt@q]
}, PlotRange->All, PlotLabel ->"q=(Q^(1/3))"]],
Dynamic[Graphics[{OutputBackground,
S=-u/6+(q+(Subscript[Δ, 0])/q)/(12a);
Text["S", Pt@S]
}, PlotRange->All, PlotLabel ->"S"]],
Dynamic[Graphics[{OutputBackground,
s=PRoot["S",S,2];
Text["s", Pt@s]
}, PlotRange->All, PlotLabel ->"s=(Sqrt[S])"]],
Dynamic[Graphics[{OutputBackground,
Γ=-4S-2u-v/s;
Text["Γ", Pt@Γ]
}, PlotRange->All, PlotLabel ->"Γ"]],
Dynamic[Graphics[{OutputBackground,
γ=PRoot["Γ4",Γ,2];
Text["γ", Pt@γ]
}, PlotRange->All, PlotLabel ->"γ=(Sqrt[Γ])"]],
Dynamic[Graphics[{OutputBackground,
r=-b/(4a)+s+γ/2;
Text["r", Pt@r]
}, PlotRange->All, PlotLabel ->"γ"]],
Null,Null
}]
]

Testing the Quartic Solution

Module[{λ1,λ2,λ3,λ4,a,b,c,d,e,x,Δ,δ,Q,S,q,s,u,v,Γ,γ,r},
{λ1,λ2,λ3,λ4}=(1/2){{1,1}, {1,-1}, {-1,1},{-1,-1}};
GraphicsGrid[Partition[#,4]& @ {
LocatorPane[Dynamic[{λ1,λ2,λ3,λ4}],InputBackground,Appearance -> {"(Subscript[λ, 1])", "(Subscript[λ, 2])", "(Subscript[λ, 3])", "(Subscript[λ, 4])"}],
Dynamic[Graphics[{OutputBackground,
{e, d,c,b,a}=CoefficientList[(x-{1,I}.λ1)(x-{1,I}.λ2)(x-{1,I}.λ3)(x-{1,I}.λ4), x];
Text["a", {Re[a],Im[a]}], Text["b", {Re[b],Im[b]}], Text["c",{Re[c],Im[c]}],Text["d",{Re[d],Im[d]}], Text["e",{Re[e],Im[e]}]
}, PlotRange->All]],
Dynamic[Graphics[{OutputBackground,
(Subscript[Δ, 0])=(c^2)-3b d+12a e;
(Subscript[Δ, 1])=2(c^3)-9b c d+27(b^2)e+27a (d^2)-72a c e;
(Subscript[Δ, 2])=(-4((Subscript[Δ, 0])^3)+((Subscript[Δ, 1])^2))/27;
u=(8 a c-3(b^2))/(8(a^2));
v=((b^3)-4a b c+8(a^2)d)/(8(a^3));
Text["(Subscript[Δ, 0])", Pt@(Subscript[Δ, 0])], Text["(Subscript[Δ, 1])", Pt@(Subscript[Δ, 1])], Text["(Subscript[Δ, 2])", Pt@(Subscript[Δ, 2])], Text["u", Pt@u], Text["v", Pt@v]
}, PlotRange->All]],
Dynamic[Graphics[{OutputBackground,
(Subscript[δ, 2])=PRoot["4Δ",(Subscript[Δ, 2]),2];
Text["(Subscript[δ, 2])", Pt@(Subscript[δ, 2])]
}, PlotRange->All, PlotLabel ->"(Subscript[δ, 2])=(Sqrt[(Subscript[Δ, 2])])"]],
Dynamic[Graphics[{OutputBackground,
Q=((Subscript[Δ, 1])+3(Sqrt[3])(Subscript[δ, 2]))/2;
Text["Q", Pt@Q]
}, PlotRange->All]],
Dynamic[Graphics[{OutputBackground,
q=PRoot["Q",Q,3];
Text["q", Pt@q]
}, PlotRange->All, PlotLabel ->"q=(Q^(1/3))"]],
Dynamic[Graphics[{OutputBackground,
S=-u/6+(q+(Subscript[Δ, 0])/q)/(12a);
Text["S", Pt@S]
}, PlotRange->All]],
Dynamic[Graphics[{OutputBackground,
s=PRoot["S",S,2];
Text["s", Pt@s]
}, PlotRange->All, PlotLabel ->"s=(Sqrt[S])"]],
Dynamic[Graphics[{OutputBackground,
Γ=-4S-2u-v/s;
Text["Γ", Pt@Γ]
}, PlotRange->All]],
Dynamic[Graphics[{OutputBackground,
γ=PRoot["Γ4",Γ,2];
Text["γ", Pt@γ]
}, PlotRange->All, PlotLabel ->"γ=(Sqrt[Γ])"]],
Dynamic[Graphics[{OutputBackground,
r=-b/(4a)+s+γ/2;
Text["r", Pt@r]
}, PlotRange->All]],
Null,Null,Null,Null
}]
]

Theorem

No such machine exists for the quintic,

(ax^5)+(bx^4)+(cx^3)+(dx^2)+ex+f=0.

The 10th Root

b1={{1,0}};
GraphicsGrid[{{LocatorPane[Dynamic[b1],InputBackground], 
Dynamic[Graphics[{OutputBackground, Point[r=PRoot["ex10",b1[[1,1]]+I b1[[1,2]],10]; {Re[r], Im[r]}]}, PlotRange->All, PlotLabel -> "A Persistent 10th Root"]]
}}]

The Key Point

The persistent root of a closed path is not necessarily a closed path, yet if a closed path is the commutator of two closed paths, its persistent root is a closed path.

Proof

Import["Proof.png"]

Advantages / Disadvantages

This proof is much simpler than the one usually presented in Galois theory classes, and in some sense it is more general - not only we show that the quintic is not soluble in radicals; in fact, the same proof also shows that the quintic is not soluble using any collection of univalent functions: exp, sin, ζ, and even log.

Yet one thing the classical proof does and we don’t: Classical Galois theory can show, and we can’t, that a specifc equation, say (x^5)-x+1=0, cannot be solved using the basic operations and roots.