Pensieve header: The polished ${\mathfrak g}_0$ invariant.

Reminder

Make sure that you have Mathematica and that you play with these programs!

The Main (Subscript[𝔤, 0]) Theorem

Raw Version. The (Subscript[𝔤, 0]) invariant of any S-component tangle T can be written in the form Z(T)=𝕆(((ωe)^(L+Q))|(∏_(i∈S))(Subscript[e, i])(Subscript[l, i])(Subscript[f, i])), where ω is a scalar (meaning, a rational function in the variables (Subscript[h, i]) and their exponentials (Subscript[t, i])=(e^(Subscript[h, i]))), where L=∑(Subscript[a, ij])(Subscript[h, i])(Subscript[l, j]) is a balanced quadratic in the variables (Subscript[h, i]) and (Subscript[l, j]) with integer coefficients (Subscript[a, ij]) and where Q=∑(Subscript[b, ij])(Subscript[e, i])(Subscript[f, j]) is a balanced quadratic in the variables (Subscript[e, i]) and (Subscript[f, j]) with scalar coefficients (Subscript[b, ij]). Furthermore, after setting (Subscript[h, i])=h and (Subscript[t, i])=t for all i, the invariant Z(T) is poly-time computable.

Proof. Indeed, as shown below,
0. (R^s)=(e^(s(h⊗l+e⊗f)))=𝕆(exp(s hl+(((e^(s h))-1)/h)ef|e⊗lf),
1. 𝕆((e^(γl+βe))|le)=𝕆((e^(γl+(e^γ)βe))|el),
2. 𝕆((e^(γl+βf))|fl)=𝕆((e^(γl+(e^γ)βf))|lf),
3. 𝕆((e^(βe+αf+δef))|fe)=𝕆(((νe)^(ν(-αβh+βe+αf+δef)))|ef), with ν=(((1+hδ))^(-1)),
and the rest is straight-forward.

The Main (Subscript[𝔤, 0]) Theorem, Polished Version

Polished Version. With (OverBar[e])=((((e^h)-1))/h)e, the (Subscript[𝔤, 0]) invariant of any S-component tangle T can be written in the form Z(T)=𝔼[ω,L,Q]=𝕆((ω^(-1))(e^(L+(ω^(-1))Q))|(∏_(i∈S))(Subscript[(OverBar[e]), i])(Subscript[l, i])(Subscript[f, i])), where ω is a scalar (meaning, a polynomial in the variables (Subscript[t, i])=(e^(Subscript[h, i]))), where L=∑(Subscript[a, ij])(Subscript[h, i])(Subscript[l, j]) is a balanced quadratic in the variables (Subscript[h, i]) and (Subscript[l, j]) with integer coefficients (Subscript[a, ij]) and where Q=∑(Subscript[b, ij])(Subscript[(OverBar[e]), i])(Subscript[f, j]) is a balanced quadratic in the variables (Subscript[(OverBar[e]), i]) and (Subscript[f, j]) with scalar coefficients (Subscript[b, ij]). Furthermore, after setting (Subscript[t, i])=t for all i, the invariant Z(T) is poly-time computable.

Partial Proof. Indeed,
0. (R^s)=(e^(s(h⊗l+e⊗f)))=𝕆(exp(s hl+s (t^((s-1)/2))(OverBar[e])f|(OverBar[e])⊗lf),
1. 𝕆((e^(γl+β (OverBar[e])))|l(OverBar[e]))=𝕆((e^(γl+(e^γ)β(OverBar[e])))|(OverBar[e])l),
2. 𝕆((e^(γl+βf))|fl)=𝕆((e^(γl+(e^γ)βf))|lf),
3. 𝕆((e^(β(OverBar[e])+αf+δ(OverBar[e])f))|f(OverBar[e]))=𝕆(((νe)^(ν((1-t)αβ+β(OverBar[e])+αf+δ(OverBar[e])f)))|(OverBar[e])f), with ν=(((1+(t-1)δ))^(-1)),
and the rest is straight-forward.

Implementation

CF[𝔼[ω_,L_,Q_]]:=Expand /@ Together /@ 𝔼[ω,L,Q];
𝔼/:𝔼[ω1_,L1_,Q1_]𝔼[ω2_,L2_,Q2_]:=CF@𝔼[ω1 ω2,L1+L2,ω2 Q1+ω1 Q2];
𝔼[ω1_,L1_,Q1_] ≡ 𝔼[ω2_,L2_,Q2_] := Expand[ω1==ω2∧L1==L2∧Q1==Q2];

𝔼[(Subscript[X, i_,j_]^(+))]:=𝔼[1, Log[(Subscript[t, i])](Subscript[l, j]),(Subscript[e, i])(Subscript[f, j])];
𝔼[(Subscript[X, i_,j_]^(-))]:=𝔼[1, - Log[(Subscript[t, i])](Subscript[l, j]),-(Subscript[t, i]^(-1))(Subscript[e, i])(Subscript[f, j])];
𝔼[p_Times] := 𝔼 /@ p;

(Subscript[NO, (Subscript[(x:f|e), i_])(Subscript[l, j_])->k_])[𝔼[ω_,L_,Q_]] :=With[{q=(E^γ)β (Subscript[x, k])+γ (Subscript[l, k])},CF[
𝔼[ω,γ (Subscript[l, k])+(L/.(Subscript[l, j])->0),ω (E^γ)β (Subscript[x, k])+(Q/.(Subscript[x, i])->0)]/.{γ->(∂_(Subscript[l, j]))L,β->(ω^(-1))(∂_(Subscript[x, i]))Q}]];

(Subscript[NO, (Subscript[f, i_])(Subscript[e, j_])->k_])[𝔼[ω_,L_,Q_]]:=With[{q=((1-(Subscript[t, k]))α β+β (Subscript[e, k])+δ (Subscript[e, k])(Subscript[f, k])+α (Subscript[f, k]))/μ},CF[
𝔼[μ ω,L,μ ω q+μ(Q/.(Subscript[f, i])|(Subscript[e, j])->0)]/.μ->1+((Subscript[t, k])-1)δ/.{α->(ω^(-1))((∂_(Subscript[f, i]))Q/.(Subscript[e, j])->0),β->(ω^(-1))((∂_(Subscript[e, j]))Q/.(Subscript[f, i])->0),δ->(ω^(-1))(∂_((Subscript[f, i]),(Subscript[e, j])))Q}]];

The Stitching Formula

(Subscript[m, i_,j_->k_])[Z_]:=Module[{x,z},CF[(Z//(Subscript[NO, (Subscript[f, i])(Subscript[e, j])->x])//(Subscript[NO, (Subscript[l, i])(Subscript[e, x])->x])//(Subscript[NO, (Subscript[f, x])(Subscript[l, j])->x]))/.(Subscript[z_, i|j|x])->(Subscript[z, k])]]

𝔼[(Subscript[X, 4,1]^(+))(Subscript[X, 2,5]^(+))(Subscript[X, 6,3]^(+))]

𝔼[(Subscript[X, 4,1]^(+))(Subscript[X, 2,5]^(+))(Subscript[X, 6,3]^(+))] // (Subscript[m, 1,2->1])

𝔼[(Subscript[X, 4,1]^(+))(Subscript[X, 2,5]^(+))(Subscript[X, 6,3]^(+))] // (Subscript[m, 1,2->1]) // (Subscript[m, 1,3->1])

𝔼[(Subscript[X, 4,1]^(+))(Subscript[X, 2,5]^(+))(Subscript[X, 6,3]^(+))] // (Subscript[m, 1,2->1]) // (Subscript[m, 1,3->1])//(Subscript[m, 1,4->1])

𝔼[(Subscript[X, 4,1]^(+))(Subscript[X, 2,5]^(+))(Subscript[X, 6,3]^(+))] // (Subscript[m, 1,2->1]) // (Subscript[m, 1,3->1])//(Subscript[m, 1,4->1])//(Subscript[m, 1,5->1])

𝔼[(Subscript[X, 4,1]^(+))(Subscript[X, 2,5]^(+))(Subscript[X, 6,3]^(+))] // (Subscript[m, 1,2->1]) // (Subscript[m, 1,3->1])//(Subscript[m, 1,4->1])//(Subscript[m, 1,5->1])//(Subscript[m, 1,6->1])

Independent Proof of Invariance

Meta-Associativity:

ζ=𝔼[ω,(∑_(i=1)^4)(∑_(j=1)^4)(Subscript[a, i,j])Log[(Subscript[t, i])](Subscript[l, j]), (∑_(i=1)^4)(∑_(j=1)^4)(Subscript[b, i,j])(Subscript[e, i])(Subscript[f, j])]

ζ // (Subscript[m, 1,2->1])

Short[ζ // (Subscript[m, 1,2->1])//(Subscript[m, 1,3->1]),5]

FullSimplify[(ζ // (Subscript[m, 1,2->1])//(Subscript[m, 1,3->1]))≡(ζ // (Subscript[m, 2,3->2])//(Subscript[m, 1,2->1]))]

Reidemeister 3:

lhs=𝔼[(Subscript[X, 1,4]^(+))(Subscript[X, 2,3]^(+))(Subscript[X, 5,6]^(+))]//(Subscript[m, 1,5->1])//(Subscript[m, 2,6->2])//(Subscript[m, 3,4->3])

rhs=𝔼[(Subscript[X, 1,2]^(+))(Subscript[X, 4,3]^(+))(Subscript[X, 5,6]^(+))]//(Subscript[m, 1,4->1])//(Subscript[m, 2,5->2])//(Subscript[m, 3,6->3])

lhs≡rhs

Homework.
1. Use the same methodology to verify (Subscript[m, a,b->c])//(Subscript[m, d,e->f])==(Subscript[m, d,e->f])//(Subscript[m, a,b->c]).
2. Likewise, verify the two types of R2 moves.
3. Make sure that R1 gives no trouble.