This mathematica notebook computes the Jones polynomial using a different normalization

Here we input the knot K as a product of crossings of the form Xp[i,j,k,l] for positive crossing or Xm[i,j,k,l] for negative crossing. We index the crossings as follows. For each crossing, we first break it into four disjoint arcs. We label the incoming understrand i, then j, k, l are the indices of the arcs as we encounter them when we go along the crossing counterclockwise starting from i. The routine is given below.

Jones2[Knot_]:=Module[{t1,t2,t3},
t1=Expand[Knot /.{
Xp[i_,j_,k_,l_]:> -(q^(1/2))*P[i,j]*P[k,l]-q*P[i,l]*P[j,k],
Xm[i_,j_,k_,l_]:>  -(q^(-1))*P[i,j]*P[k,l]-(q^(-1/2))*P[i,l]*P[j,k]}];
 SetAttributes[P,Orderless];
  t2=t1//.P[a_,b_]*P[b_,c_]:> P[a,c];  t3=Simplify[t2/.{P[i_,i_]:> (-(q^(1/2))-(q^(-1/2))), P[i_,j_]^2:> (-(q^(1/2))-(q^(-1/2)))}];
If[FreeQ[t3,P],Simplify[t3/(-(q^(1/2))-(q^(-1/2)))],t3]];

Now let’s compute the trefoil

Jones2[Xp[1,5,2,4] Xp[3,1,4,6] Xp[5,3,6,2]]

Figure eight knot

Jones2[Xm[6,1,7,2]Xm[2,5,3,6]Xp[8,4,1,3]Xp[4,8,5,7]]

Two-bridge knot 5_2

Jones2[Xm[1,8,2,9]Xm[7,2,8,3]Xm[3,6,4,7]Xm[9,4,10,5]Xm[5,10,6,1]]

The (5,2) torus knot 5_1

Jones2[Xp[1,7,2,6]Xp[7,3,8,2]Xp[3,9,4,8]Xp[9,5,10,4]Xp[5,1,6,10]]

The knot 8_17

Jones2[Xm[1,12,2,13] Xm[3,8,4,9] Xm[7,2,8,3] Xm[11,4,12,5] Xp[5,1,6,16] Xp[9,15,10,14] Xp[13,7,14,6] Xp[15,11,16,10]]

Checking R2:

Jones2[Xp[1,5,2,4]Xm[2,5,3,6]]==P[1,3]P[4,6]

Checking R3:

Jones2[Xp[4,8,5,7]Xp[1,9,2,8]Xp[2,6,3,5]]==Jones2[Xp[1,5,2,4]Xp[2,8,3,7]Xp[5,9,6,8]]

Checking R1:

Jones2[Xp[1,3,2,2]]==P[1,3]

Checking the skein relation 
            (q^(-1))Jones2[(SubPlus[L])]-q Jones2[(SubMinus[L])] = ((q^(1/2)) - (q^(-1/2)))Jones2[(Subscript[L, ∞])]
Here (SubPlus[L]) is the positive crossing, (SubMinus[L]) is the negative crossing and (Subscript[L, ∞]) is the positive smoothing

(q^(-1))Jones2[Xp[1,2,3,4]]-q Jones2[Xm[4,1,2,3]]-((q^(1/2))-(q^(-1/2)))P[1,2]P[3,4]//Simplify