Pensieve header: January 18: Fibonacci Forever.

f1[0]=1; f1[1]=1;
f1[n_] := (f1[n]=f1[n-1]+f1[n-2])

Table[f1[k], {k,1,10}]

f1[100]

f2[n_] := Module[{k=1, prev, cur},
prev=cur=1;
While[k<n, {prev,cur} = {cur, prev+cur}; ++k];
cur
]

f2[10]

f2[100]

?For

f3[n_] := (For[k=cur=prev=1, k<n, k+=1, {prev,cur} = {cur, prev+cur}]; cur)

f3[100]

?Do

f4[n_] := (
prev=cur=1;
Do[{prev,cur} = {cur, prev+cur}, n-1];
cur)

f4[100]

f4[2]

f5[n_] := {1,1,1} //. {
{n,_,c_} :> c,
{k_,p_,c_}:>{k+1, c, p+c}
}

f5[100]

Series[(1/(1-x-(x^2))), {x, 0, 10}]

Series[(1/(1-x-(x^2))), {x, 0, 10}] // FullForm

Series[(1/(1-x-(x^2))), {x, 0, 100}][[3]] // Last

SeriesCoefficient[(1/(1-x-(x^2))),{x,0,100}]

((D[(1/(1-x-(x^2))), {x,100}])/(100!)) /. x->0

f8[n_] := Sum[Binomial[n-k,k], {k,0,Floor[n/2]}]

f8[100]