Pensieve Header: Quilt Plot for 12-240.

We are studying the small scale theory of *everything*!

QuiltPlot[{f_,g_},{x_,xmin_,xmax_,nx_},{y_,ymin_,ymax_,ny_}]:=Module[
{dx,dy,grid,ix,iy},
SeedRandom[1];
dx=(xmax-xmin)/nx;
dy=(ymax-ymin)/ny;
grid=Table[
{x->xmin+ix*dx,y->ymin+iy*dy},
{ix,0,nx},{iy,0,ny}
];
grid=Map[({f,g}/.#)&,grid,{2}];
Show[
Graphics[Table[
{
RGBColor[Random[],Random[],Random[]],
Polygon[{
grid[[ix,iy]],
grid[[ix+1,iy]],
grid[[ix+1,iy+1]],
grid[[ix,iy+1]]
}]
},
{ix,nx},{iy,ny}
]],
Frame->True, AspectRatio -> 1
]
];
DoubleQuiltPlot[f_List, xrange_List, yrange_List] := GraphicsRow[{
QuiltPlot[{x,y},xrange,yrange],
QuiltPlot[f,xrange,yrange]
}]

DoubleQuiltPlot[{2x-3y, x+4y}, {x,-1,1,4}, {y,-1,1,5}]

DoubleQuiltPlot[{x^2-y^2,2*x*y}, {x,-10,10,8},{y,5,10,8}]

DoubleQuiltPlot[{E^x*Cos[y],E^x*Sin[y]}, {x,0,2,18},{y,0,Pi,18}]

DoubleQuiltPlot[{Re[Zeta[x+I y]], Im[Zeta[x+I y]]}, {x,0,2,10}, {y,1,3,10}]