Pensieve Header: Testing the log-concavity of the Alexander polynomial; inspired by “Log-concavity of the Alexander polynomial”, arXiv:2303.04733, by Elena S. Hafner, Karola Mészáros, Alexander Vidinas. Continued for $\rho_1$ (fails) at pensieve://Projects/APAI/

SetDirectory["C:\\drorbn\\AcademicPensieve\\2023-03"];
Once[<< KnotTheory`]

ConcaveQ[s_List]:=And@@Thread[2s[[2;;-2]]>=s[[1;;-3]]+s[[3;;-1]]];

alex=Alexander[Knot[8,17]][-T]
CoefficientList[(T^(Exponent[alex,T]))alex,T]
ConcaveQ[Log[Abs@CoefficientList[(T^(Exponent[alex,T]))alex,T]]]

K=Knot[8,19]
alex=Alexander[K][-T]
cs=CoefficientList[Sign[alex/.T->1](T^(Exponent[alex,T]))alex,T]
Not[And@@(Positive/@cs)]

AlexanderLogConcaveQ[K_]:=Module[{alex,T,cs},
alex=Alexander[K][-T];
cs=CoefficientList[Sign[alex/.T->1](T^(Exponent[alex,T]))alex,T];
If[Not[And@@(Positive/@cs)],Return@False];
If[Length[cs]<3, Return@True];
ConcaveQ[Log@cs]
]

NLCs=Select[AllKnots[{3,10}], Not[AlexanderLogConcaveQ[#]]&]

AlternatingQ/@NLCs

Total[
AlternatingQ/@Select[AllKnots[{11,14}], Not[AlexanderLogConcaveQ[#]]&]
]