Pensieve header: Kauffman @ A cubic root of -1.

<< KnotTheory`

KB[pd_PD] := Module[{p,t1,t2,t3,t4,B,d,KB,todo,front,x,v},
SetAttributes[p,Orderless];
KB=1;
todo=List@@pd;
front={};
v[x_X]:=Length[front⋂(List@@x)];
While[Length[todo]>0,
x=RandomChoice[MaximalBy[todo,v]];
todo=DeleteCases[todo,x];
t1=KB(x/. X[i_,j_,k_,l_]->A*p[i,j]*p[k,l]+B*p[i,l]*p[j,k]);
t2=Expand[t1];
t3=t2 //. {p[i_,j_]*p[j_,k_]->p[i,k]};
t4=t3 /. {p[i_,i_]->d, p[i_,j_]^2 ->d};
KB=Expand[t4/.{B->1/A, d->-A^2-1/A^2}];
front=Complement[front⋃(List@@x), front⋂(List@@x)];
];
KB
];
KB[K_]:=KB[PD[K]]

Short[tabK=KB/@AllKnots[{3,8}]]

Union@Simplify[tabK/. A->(E^(π I/3))]

Short[tabL=KB/@AllLinks[{2,10}]]

Union@Simplify[tabL/. A->(E^(π I/3))]

((((E^(π I/3))))^3)

((((E^(π I/3))))^(-4))

((((E^(π I/3))))^(-4))/((((E^(π I/3))))^4)

N[(-(A^2)-(A^(-2)))/.A->(E^(π I/3))]