Pensieve header: Implementing and verifying $gl_n^\epsilon$ in its “cyclic” presentation. Continues pensieve://2017-02/ (though in different directions).

n=5;

(Subscript[χ, cond_]) := If[TrueQ@cond, 1, 0];
B[0,_]=0; B[_,0]=0;
B[c_*x:(Subscript[(x|a|b), __]),y_]:=Expand[c B[x,y]];
B[y_,c_*x:(Subscript[(x|a|b), __])]:=Expand[c B[y,x]];
B[x_Plus,y_] := B[#,y]& /@ x;
B[x_,y_Plus] := B[x,#]& /@ y;
P[0,_]=0; P[_,0]=0;
P[c_*x:(Subscript[(x|a|b), __]),y_]:=Expand[c P[x,y]];
P[y_,c_*x:(Subscript[(x|a|b), __])]:=Expand[c P[y,x]];
P[x_Plus,y_] := P[#,y]& /@ x;
P[x_,y_Plus] := P[x,#]& /@ y;

P[(Subscript[x, i_,j_]), (Subscript[x, k_,l_])] := (Subscript[χ, j==k∧i==l]);
P[(Subscript[x, __]),(Subscript[(a|b), _])]=0; P[(Subscript[(a|b), _]),(Subscript[x, __])]=0;
P[(Subscript[a, i_]),(Subscript[b, j_])]:=2(Subscript[χ, i==j]); P[(Subscript[b, j_]),(Subscript[a, i_])]:=2(Subscript[χ, i==j]);
P[(Subscript[a, _]),(Subscript[a, _])]=0; P[(Subscript[b, _]),(Subscript[b, _])]=0;

λ[(Subscript[x, i_,j_])]:=Mod[j-i,n];
(Subscript[x, i_,i_]):=(Subscript[b, i])/2+ϵ (Subscript[a, i])/2

B[(Subscript[(a|b), _]),(Subscript[(a|b), _])]=0;

B[(Subscript[x, i_,j_]),(Subscript[x, k_,l_])] := (ϵ^(Subscript[χ, λ[(Subscript[x, i,j])]+λ[(Subscript[x, k,l])]>n]))((Subscript[χ, j==k])(Subscript[x, i,l])-(Subscript[χ, l==i])(Subscript[x, k,j]));

B[(Subscript[a, i_]),(Subscript[x, j_,k_])]:=((Subscript[χ, i==j])-(Subscript[χ, i==k]))(Subscript[x, j,k]);
B[(Subscript[b, i_]),(Subscript[x, j_,k_])]:=ϵ((Subscript[χ, i==j])-(Subscript[χ, i==k]))(Subscript[x, j,k]);

B[y_,x_] := Expand[-B[x,y]];

cyc[k_Integer]:=Mod[k+1,n,1];
Cyc[ℰ_]:=ℰ/.{(Subscript[x, i_,j_]):>(Subscript[x, cyc@i,cyc@j]), (Subscript[a, i_]):>(Subscript[a, cyc@i]), (Subscript[b, i_]):>(Subscript[b, cyc@i])}

(Subscript[Act, σ_List])[ℰ_]:=ℰ/.{(Subscript[x, i_,j_]):>(Subscript[x, σ[[i]],σ[[j]]]), (Subscript[a, i_]):>(Subscript[a, σ[[i]]]), (Subscript[b, i_]):>(Subscript[b, σ[[i]]])}

(Subscript[ϕ, λ_])[ℰ_] := ℰ /. {(Subscript[x, i_,j_])/;i>j:>λ (Subscript[x, i,j]), (Subscript[b, i_]):>λ (Subscript[b, i])};

Basis[n_] := Sort@Flatten[{Table[(Subscript[x, i,j]),{i,n},{j,Delete[Range[n],i]}],Table[(Subscript[a, i]),{i,n}],Table[(Subscript[b, i]),{i,n}]}];

Basis[4]

n=2;
Table[
{u,v}->B[u,v],
{u,Basis[n]}, {v,Basis[n]}
]// MatrixForm

n=4;
Union@Table[
({u,v}=t); B[u,v]+B[v,u],
{t, Tuples[Basis[n], 2]}
]

n=4;
DeleteCases[Table[
({u,v,w}=t)-> B[u,B[v,w]]+B[v,B[w,u]]+B[w,B[u,v]],
{t, Tuples[Basis[n], 3]}
], _->0]

n=4;
DeleteCases[Flatten@Table[
{u,v,w}-> P[B[u,v],w]+P[v,B[u,w]],
{u,Basis[n]}, {v,Basis[n]},{w,Basis[n]}
], _->0]

(#->Cyc[#])&/@Basis[4]

n=4;
DeleteCases[Flatten@Table[
{u,v}->Cyc[B[u,v]]-B[Cyc[u],Cyc[v]],
{u,Basis[n]}, {v,Basis[n]}
], _->0]

n=4;
DeleteCases[Flatten@Table[
{u,v}->Cyc[P[u,v]]-P[Cyc[u],Cyc[v]],
{u,Basis[n]}, {v,Basis[n]}
], _->0]

n=5;
Select[Permutations[Range[n]],
σ|->And@@Flatten[Table[
(Subscript[Act, σ])[B[u,v]]===B[(Subscript[Act, σ])[u],(Subscript[Act, σ])[v]],
{u,Basis[n]}, {v,Basis[n]}
]]
]

n=4;
Block[{ϵ=1},Select[Permutations[Range[n]],
σ|->And@@Flatten[Table[
(Subscript[Act, σ])[B[u,v]]===B[(Subscript[Act, σ])[u],(Subscript[Act, σ])[v]],
{u,Basis[n]}, {v,Basis[n]}
]]
]]

n=4;
Union@Flatten@Table[
(B[u,v]/.ϵ->1)==(Subscript[ϕ, ϵ])@B[(Subscript[ϕ, 1/ϵ])@u,(Subscript[ϕ, 1/ϵ])@v],
{u,Basis[n]},{v,Basis[n]}
]

n=4; Table[u->(Subscript[ϕ, ϵ])@(Subscript[Act, {2,3,4,1}])@(Subscript[ϕ, 1/ϵ])@u,{u,Basis[n]} ]

n=4; Table[u->(Subscript[ϕ, 1/ϵ])@(Subscript[Act, {2,3,4,1}])@(Subscript[ϕ, ϵ])@u,{u,Basis[n]} ]

n=3;MatrixForm@Table[u->(Subscript[ϕ, ϵ])@(Subscript[Act, σ])@(Subscript[ϕ, 1/ϵ])@u,{σ,Permutations@Range@n},{u,Basis[n]} ]

n=3;MatrixForm@Table[u->(Subscript[ϕ, 1/ϵ])@(Subscript[Act, σ])@(Subscript[ϕ, ϵ])@u,{σ,Permutations@Range@n},{u,Basis[n]} ]