Pensieve header: $\Delta$ and $S$ in the quantized case; evolved from pensieve://2017-09/nb/QuantizedLogos.pdf.

Some Shortcuts

ME[x_] := MatrixExp[x]; MF[x_] := MatrixForm[x];

Representing ϵyax

(Borrowed from pensieve://2017-08/Multi-beta-yax.nb)

q=(E^(ℏ γ ϵ)); ρI=(({{1, 0}, {0, 1}})); ρy=(({{0, 0}, {-1, 0}})); ρa=(({{0, 0}, {0, -γ}}));ρx=(({{0, ((-1+(E^(-γ ϵ ℏ)))/ℏ)}, {0, 0}})); ρb=(({{ϵ, 0}, {0, 0}}));
ρt=Simplify[ϵ ρa-γ ρb]; ρA=ME[-ℏ ϵ ρa];  ρB=ME[-ℏ γ ρb];  ρT=ME[ℏ ρt];
(#->MF@Simplify@ToExpression@#)& /@ {"{{q}}", "ρy","ρa","ρx","ρb", "ρt", "ρA", "ρB", "ρT", "ρI"}

{ρa.ρx-ρx.ρa==γ ρx, ρx.ρA==q ρA.ρx, ρa.ρy-ρy.ρa==-γ ρy, ρb.ρy-ρy.ρb==-ϵ ρy, ρx.ρy-q ρy.ρx==(ρI-ρT.ρA.ρA)/ℏ} // Simplify

Δ(x)

Note that Δ(x)=x⊗1+A⊗x. We can regard the second tensor factor as commuting coefficients.

MF /@ (eqn=ME[ξ(ρx+x ρA)]==ME[α0 ρA].ME[ξ0 ρx])

Thread[Flatten /@ eqn/. α0 -> ξ x]

sol=Solve[Thread[Flatten /@ eqn/. α0 -> ξ x], {ξ0}][[1]]

FullSimplify[ξ0 /. sol]

Series[ξ0 /. sol, {ϵ,0,3}]

S(x)

Note that S(x)=-(A^(-1))x.

-Inverse[ρA].ρx //Simplify //  MF

MF /@ (eqn=ME[-ξ Inverse[ρA].ρx]==ME[ξ0 ρx])

Thread[Flatten /@ eqn]

sol=Solve[Thread[Flatten /@ eqn], {ξ0}][[1]]

FullSimplify[ξ0 /. sol]

Series[ξ0 /. sol, {ϵ,0,3}]

Δ(y)

Note that Δ(y)=y⊗B+1⊗y. We can regard the first tensor factor as commuting coefficients.

MF /@ (eqn=ME[η(y ρB+ρy)]==ME[η0 ρy].ME[β0 ρB])

Thread[Flatten /@ eqn/. β0 -> η y]

sol=Solve[Thread[Flatten /@ eqn/. β0 -> η y], {η0}][[1]]

FullSimplify[η0 /. sol]

Series[η0 /. sol, {ϵ,0,3}]