Pensieve header: One-Co computations in the abc presentation; continued pensieve://2015-08/.

The bracket

On the elements β, a, c, δa, ca, δaa.

Generalities

DQ[is___] := (Sort[{is}]===Union[{is}]);
OQ[is___] := OrderedQ[{is}];

Simp[expr_] := Simplify[expr];
S[β[f_]] := β[Simp[f]];
S[a[i_,j_]] := a[i,j];
S[a[f_, i_,j_]] := a[Simp[f], i,j];
S[c[f_, k_]] := c[Simp[f], k];
S[δa[f_, i_,j_]] := δa[Simp[f], i,j];
S[ca[f_, j_,k_,l_]] := ca[Simp[f], j,k,l];
S[δaa[f_, i_,j_,k_,l_]] := δaa[Simp[f], i,j,k,l];
S[expr_] := expr /. (λ_β|λ_a|λ_δa|λ_c|λ_ca|λ_δaa) :> S[λ];

β[0] :=0;
β /: β[f_] + β[g_] := β[f+g] // S;
β /: g_*β[f_] := β[g f] // S;
a[0,_,_] := 0;
a /: a[f_,j_,k_] + a[g_, j_,k_] := a[f+g, j,k] // S;
a /: g_*a[f_, j_,k_] := a[g f, j,k] // S;
c[0,_] :=0;
c /: c[f_,j_] + c[g_, j_] := c[f+g, j] // S;
c/: g_*c[f_, j_] := c[g f, j] // S;
δa[0,_,_] := 0;
δa /: δa[f_,j_,k_] + δa[g_, j_,k_] := δa[f+g, j,k] // S;
δa /: g_*δa[f_, j_,k_] := δa[g f, j,k] // S;
ca[0,_,_,_] :=0;
ca /: ca[f_,j_,k_,l_] + ca[g_, j_,k_,l_] := ca[f+g, j,k,l] // S;
ca /: g_*ca[f_, j_,k_,l_] := ca[g f, j,k,l] // S;
δaa[0, _,_,_,_] :=0;
δaa /: δaa[f_,i_,j_,k_,l_] + δaa[g_, i_,j_,k_,l_] := δaa[f+g, i,j,k,l] // S;
δaa /: g_*δaa[f_, i_,j_,k_,l_] := δaa[g f, i,j,k,l] // S;

δaa relations

(Subscript[ϵ, 1])=1;

Locality:

S[δaa[f_,i_,j_,k_,l_]] /; ({i,j}⋂{k,l}==={})∧!OQ[i,k] := δaa[f,k,l,i,j] // S;

Standard Swinging:

S[δaa[f_,i_,j_,k_,l_]] /; DQ[i,j,k,l]∧OQ[i,k]∧!OQ[j,l] := S[Expand[
δaa[f,i,l,k,j]+(Subscript[ϵ, 1])(ca[(Subscript[b, k])f,l,i,j]-ca[(Subscript[b, i])f,l,k,j]-ca[(Subscript[b, k])f,j,i,l]+ca[(Subscript[b, i])f,j,k,l])
]];

1322 Swinging:

S[δaa[f_,i_,j_,k_,k_]] /; DQ[i,j,k]∧OQ[i,k,j]:= S[Expand[
δaa[f,i,k,k,j]+(Subscript[ϵ, 1])(ca[(Subscript[b, k])f,k,i,j]-ca[(Subscript[b, i])f,k,k,j]-ca[(Subscript[b, k])f,j,i,k]+ca[(Subscript[b, i])f,j,k,k])+(Subscript[ϵ, 3])(δa[(Subscript[b, i])f,k,j]-c[(Subscript[b, i])(Subscript[b, k]),j])
]];

Tails Commute:

S[δaa[f_,i_,j_,i_,l_]] /; DQ[i,j,l]∧!OQ[j,l] := δaa[f,i,l,i,j] // S;

Commute Heads:

S[δaa[f_,i_,k_,j_,k_]] /; DQ[i,j,k]∧!OQ[i,j] := S[Expand[
δaa[f,j,k,i,k] + (Subscript[ϵ, 2])(δa[(Subscript[b, i])f,j,k]-δa[(Subscript[b, j])f,i,k])
]];

Commute Heads/Tails:

S[δaa[f_,i_,j_,k_,i_]] /; DQ[i,j,k]∧!OQ[i,k] := S[
δaa[f,k,i,i,j]+δaa[f,k,j,i,j]-δaa[f,i,j,k,j]
];

NonCommutativeMultiply

Unprotect[NonCommutativeMultiply];
NonCommutativeMultiply[0,_] =0; NonCommutativeMultiply[_, 0] = 0;
NonCommutativeMultiply[x_,x_] = 0;
NonCommutativeMultiply[x_Plus, y_] := NonCommutativeMultiply[#,y]& /@ x;
NonCommutativeMultiply[x_, y_Plus] := NonCommutativeMultiply[x,#]& /@ y;

β[f_]**a[g_,j_,k_] := a[f g, j,k];
β[f_]**c[g_,j_] := c[f g, j];
c[g_,j_] ** β[f_] := c[f g, j];
β[f_]**δa[g_,j_,k_] := δa[f g, j,k];
β[f_]**ca[g_,i_,j_,k_] := ca[f g, i,j,k];
β[f_]**δaa[g_,i_,j_,k_,l_] := δaa[f g, i,j,k,l];
δa[g_,j_,k_] ** β[f_] := δa[f g, j,k];
δ**a[f_,i_,j_] := δa[f,i,j];
c[f_,i_]**a[g_,j_,k_] := ca[f g, i,j,k];
a[f_,i_,j_]**δa[g_,k_,l_] := δaa[f g,i,j,k,l];
δa[f_,i_,j_]**a[g_,k_,l_] := δaa[f g,i,j,k,l];

δ**_c = 0;
δ**_δa = 0;
δ**_ca = 0;
δ**_δaa = 0;
_c**_c=0;
_c**_δa = _δa**_c = 0;
_c**_ca = _ca**_c = 0;
_c**_δaa = _δaa**_c = 0;
_δa**_δa = 0;
_δa**_δaa = _δaa**_δa = 0;
_δa**_ca = _ca**_δa = 0;

NonCommutativeMultiply::ndef = "NonCommuatativeMultiply is not defined on {`1`,`2`}."
NonCommutativeMultiply[x_,y_] := (Message[NonCommutativeMultiply::ndef, x,y]; Undefined);

Bracket Generalities

B[0,_] =0; B[_, 0] = 0;
B[x_,x_] = 0;
B[x_Plus, y_] := B[#,y]& /@ x;
B[x_, y_Plus] := B[x,#]& /@ y;

The γ shortcuts

γ[f_, j_,k_] := δa[f,j,k]-c[(Subscript[b, j])f,k] // S;
γ[f_, j_,k_,l_] /; DQ[j,k,l] := ca[f,l,j,k] - ca[f,k,j,l] // S;

Fundamental Brackets

a-β, a-c, a-a, AS

B[a[j_,k_],β[g_]]:=γ[(∂_(Subscript[b, j]))g-(∂_(Subscript[b, k]))g,j,k];
B[β[g_], a[j_,k_]] := -B[a[j,k], β[g]];
B[a[j_,k_],a[l_,m_]] /; ({j,k}⋂{l,m}==={}) := 0;B[a[j_,k_],a[j_,l_]]/;DQ[j,k,l]:=γ[1,j,k,l] // S;
B[a[j_,k_],a[i_,k_]]/;DQ[i,j,k]:=a[(Subscript[b, i]),j,k]-a[(Subscript[b, j]),i,k] // S;
B[a[j_,k_],a[k_,l_]]/;DQ[j,k,l]:=a[(Subscript[b, j]),k,l]-a[(Subscript[b, k]),j,l]-γ[1,j,k,l] // S;
B[a[k_,l_], a[j_,k_]]/;DQ[j,k,l]:= -B[a[j,k],a[k,l]];
B[a[j_,k_], a[k_,j_]] /; DQ[j,k] := a[(Subscript[b, j]),k,j]-a[(Subscript[b, k]),j,k]+a[(Subscript[b, j]),k,k]-a[(Subscript[b, k]),j,j]+ca[1,k,k,j]-ca[1,j,j,k]+ca[1,k,j,j]-ca[1,j,k,k]+γ[1,j,k]-γ[1,k,j];
B[a[j_,k_], a[j_,j_]] /; DQ[j,k] := -γ[1,j,k] //S;
B[a[j_,j_], a[j_,k_]] /; DQ[j,k] := -B[a[j,k], a[j,j]];
B[a[j_,k_], a[k_,k_]] /; DQ[j,k] := -γ[1,j,k] //S;
B[a[k_,k_], a[j_,k_]] /; DQ[j,k] := -B[a[j,k], a[j,j]];
B[a[f_,j_,k_], c[g_,j_]] /; DQ[j,k] := γ[-f g,j,k];
B[a[f_,j_,k_], c[g_,k_]] /; DQ[j,k] := γ[f g,j,k];
B[a[f_,j_,k_], c[g_,l_]] /; ({j,k}⋂{l}==={}) := 0;
B[a[f_,j_,j_], c[g_,j_]] = 0;
B[c[g_,l_], a[f_,j_,k_]] := -B[a[f,j,k], c[g,l]];

Vanishing brackets

B[_β, _β|δ|_c|_δa|_ca|_δaa] = 0;
B[_β|δ|_c|_δa|_ca|_δaa, _β] = 0;
B[δ|_c|_δa|_ca|_δaa, δ|_c|_δa|_ca|_δaa] = 0;

Composite Brackets

B[a[f_, j_,k_],β[g_]] :=β[f]**B[a[j,k],β[g]];
B[β[g_], a[f_, j_,k_]] := -B[a[f,j,k], β[g]];
B[a[f_, j_,k_], a[l_,m_]] := B[β[f], a[l,m]]**a[1,j,k] + β[f]**B[a[j,k], a[l,m]];
B[a[f_, j_,k_], a[g_, l_,m_]] := B[a[f,j,k], β[g]]**a[1,l,m] + β[g]**B[a[f,j,k], a[l,m]];
B[a[f_,i_,j_], δa[g_,k_,l_]] := δ**B[a[f,i,j], a[g,k,l]];
B[δa[f_,i_,j_], a[g_,k_,l_]] := δ**B[a[f,i,j], a[g,k,l]];
B[a[f_,i_,j_], ca[g_,k_,l_,m_]] := B[a[f,i,j], c[g,k]]**a[1,l,m]+c[g,k]**B[a[f,i,j],a[l,m]];
B[ca[g_,k_,l_,m_], a[f_,i_,j_]] := -B[a[f,i,j], ca[g,k,l,m]];
B[a[f_,i_,j_], δaa[g_,k_,l_,m_,n_]] := B[a[f,i,j], δa[g,k,l]]**a[1,m,n]+δa[g,k,l]**B[a[f,i,j],a[m,n]];
B[δaa[g_,k_,l_,m_,n_], a[f_,i_,j_]] := -B[a[f,i,j], δaa[g,k,l,m,n]];

B::ndef = "B is not defined on {`1`,`2`}."
B[x_,y_] := (Message[B::ndef, x,y]; Undefined);

Testing Jacobi and Anti-Symmetry

FormalBasis[n_, f_] := Module[{ff},
ff=f@@Table[(Subscript[b, i]), {i,n}];
Flatten@{
β[ff],
Table[a[ff, i,j], {i,n}, {j,n}],
Table[c[ff, i], {i,n}],
Table[δa[ff, i,j], {i,n}, {j,n}],
Table[ca[ff, i,j,k], {i,n}, {j,n}, {k,n}],
Table[δaa[ff, i,j,k,l], {i,n},{j,n},{k,i,n},{l,j,n}]
} /. 1[___] -> 1
];
FormalPlusBasis[n_, f_] := Module[{ff},
ff=f@@Table[(Subscript[b, i]), {i,n}];
Flatten@{
β[ff],
Table[a[ff, i,j], {i,n-1}, {j,i+1,n}],
Table[c[ff, i], {i,n}],
Table[δa[ff, i,j], {i,n-1}, {j,i+1,n}],
Table[ca[ff, i,j,k], {i,n}, {j,n-1}, {k, j+1,n}],
Table[δaa[ff, i,j,k,l], {i,n-1},{j,i+1,n},{k,n-1},{l,k+1,n}]
} /. 1[___] -> 1
];

FormalPlusBasis[3, f]

AS[x1_,x2_] := Module[{as},
as=B[x1,x2]+B[x2,x1] // S;
If[as===0,as,{x1,x2} ->  as]
];
DeleteCases[Flatten[Outer[
AS,
FormalPlusBasis[3,f],
FormalPlusBasis[3,g]
]], 0]

AS[x1_,x2_] := Module[{as},
as=B[x1,x2]+B[x2,x1] // S;
If[as===0,as,{x1,x2} ->  as]
];
DeleteCases[Flatten[Outer[
AS,
FormalBasis[3,f],
FormalBasis[3,g]
]], 0]

Jacobi[x1_,x2_,x3_] := Module[{Jac},
Jac=S[B[x1,B[x2,x3]] + B[x2,B[x3,x1]] + B[x3,B[x1,x2]]];
If[Jac===0,Jac,{x1,x2,x3} ->  Jac]
];

JacPlusErrors=DeleteCases[
bas1=FormalPlusBasis[4,f];
bas2=FormalPlusBasis[4,g];
bas3=FormalPlusBasis[4,h];
Flatten[
Table[Jacobi[bas1[[i]],bas2[[j]],bas3[[k]]],
{i,Length[bas1]-1}, {j, i+1,Length@bas2}, {k,i+1,Length@bas3}]
],
0]

JacPlusErrors//Length

JacErrors=DeleteCases[
bas1=FormalBasis[4,f];
bas2=FormalBasis[4,g];
bas3=FormalBasis[4,h];
Flatten[
Table[Jacobi[bas1[[i]],bas2[[j]],bas3[[k]]],
{i,Length[bas1]-1}, {j, i+1,Length@bas2}, {k,i+1,Length@bas3}]
],
0]

JacErrors//Length

The Adjoint action

AutoAd

AutoAd[x_][y_] := Module[{pows, states, i, s, seq,sh=5, dseq, sf1, sf2, sf, t1, n},
pows = NestList[B[x,#]&, y, 20];
Print["pows computed for ",{x,y},"..."];
states = Union[Cases[pows, s_β|s_a|s_c|s_δa|s_ca|s_δaa :> ReplacePart[s, 1->_], ∞]];
Sum[
seq=Cases[{#},states[[i]], ∞]& /@ pows;
seq=Replace[seq,{{_[f_,___]}:>f, {}->0}, {1}];
Print["seq computed... ",states[[i]]," is ",i,"/", Length@states];
dseq=Drop[seq, sh];
If[Union[Length[MonomialList[#]]& /@ dseq]==={1}∧Union[Length[FactorTermsList[#]]& /@ dseq]==={2},
sf1 = FindSequenceFunction[FactorTermsList[#][[1]]& /@ dseq];
sf2 = FindSequenceFunction[FactorTermsList[#][[2]]& /@ dseq];
Print["sf1: ", sf1, " sf2: ",sf2];
sf = (sf1[#]sf2[#]&),
(*Else*) sf=FindSequenceFunction[dseq, FunctionSpace->{"ConstantRecursive","HolonomicSequence", "Polynomial", "RationalFunction","HypergeometricTerm"}];
Print["sf: ", sf];
];
ReplacePart[states[[i]], 1 ->Simplify[ (∑_(n=0)^(sh-1))((seq[[n+1]])/(n!))+ (∑_(n=sh)^∞)((sf[n+1-sh])/(n!))]],
{i,Length@states}]
];
(* Hint: Perhaps improve using Variables, CoefficientList, FromCoefficientList *)

AutoAd[a[t,j,k]][β[f[(Subscript[b, j]),(Subscript[b, k])]]]

Ad

Ad[a[t_,j_,k_]][β[f_]] /; FreeQ[t,(Subscript[b, _])] := β[f]+c[(1-(E^(-t (Subscript[b, j]))))((∂_(Subscript[b, k]))f-(∂_(Subscript[b, j]))f),k]+δa[((((E^(-t (Subscript[b, j])))-1) ((∂_(Subscript[b, k]))f-(∂_(Subscript[b, j]))f))/(Subscript[b, j])),j,k];
Ad[a[t_,j_,k_]][a[1,j_,k_]] /; FreeQ[t,(Subscript[b, _])] := a[1,j,k];
Ad[a[t_,j_,k_]][a[1,n_,i_]] /; FreeQ[t,(Subscript[b, _])]∧({j,k}⋂{n,i}==={}) := a[1,n,i];
Ad[a[t_,j_,k_]][a[1,i_,j_]] /; DQ[i,j,k]∧FreeQ[t,(Subscript[b, _])] := a[1,i,j]+a[1-(E^(-t (Subscript[b, j]))),i,k]+a[((((E^(-t (Subscript[b, j])))-1) (Subscript[b, i]))/(Subscript[b, j])),j,k]+ca[((1-(E^(-t (Subscript[b, j]))))/(Subscript[b, j])),k,i,j]+ca[(((E^(-t (Subscript[b, j])))-1)/(Subscript[b, j])),j,i,k]+ca[(((Subscript[b, i]) (1-(E^(-t (Subscript[b, j])))-t (Subscript[b, j])))/(Subscript[b, j]^2)),j,j,k]+ca[(((E^(-2 t (Subscript[b, j]))) (Subscript[b, i]) (1-(E^(t (Subscript[b, j])))-(E^(t (Subscript[b, j]))) ((E^(t (Subscript[b, j])))-2) t (Subscript[b, j])))/(Subscript[b, j]^2)),k,j,k]+ca[(((E^(-2 t (Subscript[b, j]))) ((E^(t (Subscript[b, j]))) (1-t (Subscript[b, j]))-1))/(Subscript[b, j])),k,i,k]+δa[(((Subscript[b, i]) (-1+(E^(-t (Subscript[b, j])))+t (Subscript[b, j])) (Subscript[ϵ, 2]))/(Subscript[b, j]^2))+(((Subscript[b, i]) (1-(E^(-2 t (Subscript[b, j])))+(-1-(E^(-t (Subscript[b, j])))) t (Subscript[b, j])) (Subscript[ϵ, 2]))/(Subscript[b, j]^2)),j,k]+δa[-(((-1+(E^(-t (Subscript[b, j])))+t (Subscript[b, j])) (Subscript[ϵ, 2]))/(Subscript[b, j]))-(((1-(E^(-2 t (Subscript[b, j])))+(-1-(E^(-t (Subscript[b, j])))) t (Subscript[b, j])) (Subscript[ϵ, 2]))/(Subscript[b, j])),i,k]+δaa[((2 (E^(-t (Subscript[b, j]))) (Subscript[b, i]) (Sinh[t (Subscript[b, j])]-t (Subscript[b, j])))/(Subscript[b, j]^3)),j,k,j,k]+δaa[((-1+(E^(-t (Subscript[b, j])))+t (Subscript[b, j]))/(Subscript[b, j]^2)),i,j,j,k]+δaa[-((1-(E^(-2 t (Subscript[b, j])))+(-1-(E^(-t (Subscript[b, j])))) t (Subscript[b, j]))/(Subscript[b, j]^2)),i,k,j,k];
Ad[a[t_,j_,k_]][a[1,i_,k_]] /; DQ[i,j,k]∧FreeQ[t,(Subscript[b, _])] := a[(E^(-t (Subscript[b, j]))),i,k]+a[(((1-(E^(-t (Subscript[b, j])))) (Subscript[b, i]))/(Subscript[b, j])),j,k]+ca[((2 (E^(-t (Subscript[b, j]))) (Subscript[b, i]) (Sinh[t (Subscript[b, j])]-t (Subscript[b, j])))/(Subscript[b, j]^2)),k,j,k]+ca[(((E^(-2 t (Subscript[b, j]))) (1+(E^(t (Subscript[b, j]))) (-1+t (Subscript[b, j]))))/(Subscript[b, j])),k,i,k]+δa[-(((E^(-2 t (Subscript[b, j]))) (Subscript[b, i]) (-1+(E^(t (Subscript[b, j]))) (1-t (Subscript[b, j]))) (Subscript[ϵ, 2]))/(Subscript[b, j]^2)),j,k]+δa[(((E^(-2 t (Subscript[b, j]))) (-1+(E^(t (Subscript[b, j]))) (1-t (Subscript[b, j]))) (Subscript[ϵ, 2]))/(Subscript[b, j])),i,k]+δaa[((2 (E^(-t (Subscript[b, j]))) (Subscript[b, i]) (-Sinh[t (Subscript[b, j])]+t (Subscript[b, j])))/(Subscript[b, j]^3)),j,k,j,k]+δaa[(((E^(-2 t (Subscript[b, j]))) (-1+(E^(t (Subscript[b, j]))) (1-t (Subscript[b, j]))))/(Subscript[b, j]^2)),i,k,j,k];
Ad[a[t_,j_,k_]][a[1,j_,l_]] /; DQ[j,k,l]∧FreeQ[t,(Subscript[b, _])] := a[1,j,l]+ca[t,l,j,k]+ca[(((E^(-t (Subscript[b, j])))-1)/(Subscript[b, j])),k,j,l]+δaa[((1-(E^(-t (Subscript[b, j])))-t (Subscript[b, j]))/(Subscript[b, j]^2)),j,k,j,l];
Ad[a[t_,j_,k_]][a[1,k_,l_]] /; DQ[j,k,l]∧FreeQ[t,(Subscript[b, _])] := a[(E^(t (Subscript[b, j]))),k,l]+a[-(((-1+(E^(t (Subscript[b, j])))) (Subscript[b, k]))/(Subscript[b, j])),j,l]+ca[((-1+(E^(t (Subscript[b, j]))) (1-t (Subscript[b, j])))/(Subscript[b, j])),k,k,l]+ca[(((Subscript[b, j])-(E^(-t (Subscript[b, j]))) (Subscript[b, j])+(Subscript[b, k])+(E^(t (Subscript[b, j]))) (-1+t (Subscript[b, j])) (Subscript[b, k]))/(Subscript[b, j]^2)),k,j,l]+ca[(((Subscript[b, j])+(Subscript[b, k])+t (Subscript[b, j]) (Subscript[b, k])-(E^(t (Subscript[b, j]))) ((Subscript[b, j])+(Subscript[b, k])))/(Subscript[b, j]^2)),l,j,k]+δaa[((1+(E^(t (Subscript[b, j]))) (-1+t (Subscript[b, j])))/(Subscript[b, j]^2)),j,k,k,l]+δaa[(((E^(-t (Subscript[b, j]))) ((Subscript[b, j])+(E^(2 t (Subscript[b, j]))) ((Subscript[b, j])+(2-t (Subscript[b, j])) (Subscript[b, k]))-(E^(t (Subscript[b, j]))) (2 (Subscript[b, k])+(Subscript[b, j]) (2+t (Subscript[b, k])))))/(Subscript[b, j]^3)),j,k,j,l];
Ad[a[t_,j_,k_]][c[1,i_]] /; FreeQ[t,(Subscript[b, _])]∧({j,k}⋂{i}==={}) := c[1,i];
Ad[a[t_,j_,k_]][c[1,j_]] /; DQ[j,k]∧FreeQ[t,(Subscript[b, _])] := c[1,j]+c[1-(E^(-t (Subscript[b, j]))),k]+δa[(((E^(-t (Subscript[b, j])))-1)/(Subscript[b, j])),j,k];
Ad[a[t_,j_,k_]][c[1,k_]] /; DQ[j,k]∧FreeQ[t,(Subscript[b, _])] := c[(E^(-t (Subscript[b, j]))),k]+δa[((1-(E^(-t (Subscript[b, j]))))/(Subscript[b, j])),j,k];

Ad[x_β|x_c|x_δa|x_ca|x_δaa][y_] := y+B[x,y];

Ad[x_][a[f_,i_,j_]] /; f=!=1 := Ad[x][β[f]]**Ad[x][a[1,i,j]];
Ad[x_][c[f_,i_]] /; f=!=1 := Ad[x][β[f]]**Ad[x][c[1,i]];
Ad[x_][δa[f_,j_,k_]] := δ**(β[f]**Ad[x][a[1,j,k]]);
Ad[x_][ca[f_,i_,j_,k_]] := Ad[x][c[f,i]]**Ad[x][a[1,j,k]];
Ad[x_][δaa[f_,i_,j_,k_,l_]] := Ad[x][δa[f,i,j]]**Ad[x][a[1,k,l]];
Ad[x_][y_Plus] := Ad[x] /@ y;

Ad::ndef = "Ad[`1` is not defined on `2`.";
Ad[x_][y_] := (Message[Ad::ndef, x,y]; Undefined);

AutoAd - Ad tests

Module[{t1,t2},
{t1=S[AutoAd[a[t,j,k]][#]],
S[Ad[a[t,j,k]][#] - t1]}
]& @ a[1,i,k]

AdTests[a[t,j,k]] = {β[f[(Subscript[b, j]),(Subscript[b, k])]], a[1,j,k],a[1,n,i],c[1, i], c[1, j],c[1, k],a[1,j,l],a[1,i,j],a[1,i,k], a[1,k,l]};

S[AutoAd[a[t,j,k]][#]-Ad[a[t,j,k]][#]]& /@ Take[AdTests[a[t,j,k]],All]

The semi group properties

Module[{t1,t2,t3,t4},
t1=Ad[a[t,j,k]][#] /. (h:(β|a|c|δa|ca|δaa))[c_,r___] :> h[SeriesCoefficient[c,{t,0,1}],r];
t2=B[a[1,j,k], #];
t3=# // Ad[a[t,j,k]] // Ad[a[s,j,k]];
t4=# // Ad[a[t+s,j,k]];
# -> S[{t1==t2,t3-t4}]
]& /@ AdTests[a[t,j,k]] // ColumnForm

R

Switch[6,
0, R[i_,j_][x_] := Ad[a[1,i,j]][x],
1, R[i_,j_][x_] := Ad[a[1,i,j]][x] + B[a[t (Subscript[b, i]),i,j], Ad[a[1,i,j]][x]],
2, R[i_,j_][x_] := x // Ad[a[1,i,j]] // Ad[β[r[(Subscript[b, i]),(Subscript[b, j])]]],
3, R[i_,j_][x_] := x // Ad[a[1,i,j]] // Ad[β[f0[(Subscript[b, j])]+(Subscript[b, i])f1[(Subscript[b, j])]]],
4, R[i_,j_][x_] := x // Ad[a[1,i,j]] // Ad[c[f3[(Subscript[b, i]),(Subscript[b, j])],i]] // Ad[c[f4[(Subscript[b, i]),(Subscript[b, j])],j]],
5, R[i_,j_][x_] := x // Ad[a[1,i,j]] // Ad[ca[f5[(Subscript[b, i])],i,i,j]],
6, R[i_,j_][x_] := x // Ad[a[1,i,j]] // Ad[ca[f6[(Subscript[b, i]),(Subscript[b, j])],j,i,j]],
7, R[i_,j_][x_] := x // Ad[a[1,i,j]] // Ad[ca[f5[(Subscript[b, i])],i,i,j]]// Ad[ca[f6[(Subscript[b, i]),(Subscript[b, j])],j,i,j]]
];
VerifyR3[expr_] := Module[{lhs,rhs}, {
lhs = expr // R[1,2] // R[1,3] // R[2,3] // S;
rhs = expr // R[2,3] // R[1,3] // R[1,2] // S;
S[lhs-rhs]==0
}]

Verifying R3

VerifyR3 /@ {β[f[(Subscript[b, 1]),(Subscript[b, 2]),(Subscript[b, 3]),(Subscript[b, 4])]],c[f[(Subscript[b, 1]),(Subscript[b, 2]),(Subscript[b, 3]),(Subscript[b, 4])],1],c[f[(Subscript[b, 1]),(Subscript[b, 2]),(Subscript[b, 3]),(Subscript[b, 4])],2],c[f[(Subscript[b, 1]),(Subscript[b, 2]),(Subscript[b, 3]),(Subscript[b, 4])],3],δa[f[(Subscript[b, 1]),(Subscript[b, 2]),(Subscript[b, 3]),(Subscript[b, 4])],1,2], δa[f[(Subscript[b, 1]),(Subscript[b, 2]),(Subscript[b, 3]),(Subscript[b, 4])],1,3],δa[f[(Subscript[b, 1]),(Subscript[b, 2]),(Subscript[b, 3]),(Subscript[b, 4])],2,3], a[f[(Subscript[b, 1]),(Subscript[b, 2]),(Subscript[b, 3]),(Subscript[b, 4])],1,4], a[f,2,4]}