Pensieve Header: First consistent sighting of the MVA in β-calculus.

<< KnotTheory`
GD[K_] := GD @@ (
PD[K] /. X[i_,j_,k_,l_] :> If[PositiveQ[X[i,j,k,l]],
Ar[l,i,+1], Ar[j,i,-1]
]
)

βSimplify=Factor;
SetAttributes[βCollect, Listable];
βCollect[B[ω_, μ_]] := B[
βSimplify[ω],
Collect[μ, _h, Collect[#, _t, βSimplify]&]
];
(* "L" for "Labels" *)
hL[β_] := Union[Cases[β, h[s_] :> s, Infinity]];
tL[β_] := Union[Cases[β, t[s_]|(Subscript[T, s_]) :> s, Infinity]];
dL[β_] := Union[hL[β], tL[β]];
βForm[B[ω_, μ_]] := Module[
{tails, heads, mat},
tails = tL[B[ω, μ]]; heads = hL[B[ω, μ]];
mat = Outer[βSimplify[Coefficient[μ, h[#1] t[#2]]]&, heads, tails];
PrependTo[mat, t /@ tails];
mat = Prepend[Transpose[mat], Prepend[h /@ heads, ω]];
MatrixForm[mat]
];
βForm[else_] := else /. {β_B :> βForm[β], β_Bu :> βForm[β]};

tm[x_, y_, z_][β_] := β /. {t[x]->t[z], t[y]->t[z], (Subscript[T, x])->(Subscript[T, z]), (Subscript[T, y])->(Subscript[T, z])};
hm[x_, y_, z_][B[ω_, μ_]] := Module[
{γx= D[μ, h[x]], γy=D[μ, h[y]], M=μ /. h[x]|h[y] -> 0},
B[ω, M+h[z](γx+γy+(γx /. t[i_] :> 1)γy)] // βCollect
];
thswap[y_,x_][B[ω_, μ_]] := Module[
{α, β, γ, δ, ϵ},
α = Coefficient[μ, h[x]t[y]];
β = D[μ, t[y]] /. h[x] -> 0;
γ = D[μ, h[x]] /. t[y] -> 0;
δ = μ /. h[x]|t[y] -> 0;
ϵ = 1+α;
B[ω*ϵ, Plus[
α(1+(γ /. t[i_] :> 1)/ϵ)h[x]t[y],
β(1+(γ /. t[i_] :> 1)/ϵ)t[y],
γ/ϵ h[x],
δ-1/ϵ γ*β
]] // βCollect
];
dm[x_,y_,z_][β_] := β // thswap[x,y] // hm[x,y,z] // tm[x,y,z];
B /: B[ω1_, μ1_]B[ω2_, μ2_] := B[ω1*ω2, μ1+μ2];
R[x_, y_] := B[1, ((Subscript[T, x])-1)*t[x]h[y]];
Ri[x_, y_] := B[1, (1/(Subscript[T, x])-1)*t[x]h[y]];

βZ[L_Link] := Module[
{skel, β, s, k},
skel=Skeleton[L];
β=Times @@ GD[L] /. {Ar[x_,y_,+1] :> R[x,y],  Ar[x_,y_, -1] :> Ri[x,y]};
Do[
Do[
β = β // dm[skel[[s,1]], skel[[s,k]], skel[[s,1]]],
{k, 2, Length[skel[[s]]]}
],
{s, Length[skel]}
];
β
]

(MVA=MultivariableAlexander)[L=Link["L6a5"]][T] /. T[i_] :> (Subscript[T, i])

(β0 = βZ[L]) // βForm

(β1= βCollect[β0 /. B[ω_, μ_] :> B[ω, ω*μ]]) // βForm

Collect[β0[[2]] /. t[i_] :> 1, _h, Simplify[1+#]&]

βCollect[Bu[ω_, λ_, μ_]] := Bu[
βSimplify[ω],
Collect[λ, _h, βSimplify],
Collect[μ, _h, Collect[#, _t, βSimplify]&]
];
βForm[Bu[ω_, λ_, μ_]] := Module[
{tails, heads, mat},
tails = tL[B[ω, λ, μ]];
heads = hL[B[ω, λ, μ]];
mat = Outer[βSimplify[Coefficient[μ, h[#1] t[#2]]]&, heads, tails];
PrependTo[mat, t /@ tails];
mat = Prepend[Transpose[mat], Prepend[λ, ω]];
MatrixForm[mat]
];
Bu[n_Integer, β_B] := Bu[h /@ Range[n], β];
Bu[ηs_List, B[ω_, μ_]] :=  Module[{λ},
λ = (1+Coefficient[μ, #] /. t[i_] -> 1)& /@ ηs;
Bu[ω,
Thread[ηs -> λ],
-μ +(ηs /. h[j_] :> t[j]h[j]).λ
] // βCollect
];
B[Bu[ω_, λ_, μ_]] := 0;

{β0, β1=Bu[h/@{1,5,9},β0], Last[β1] /. t[i_] :> 1 // Simplify} // βForm

Bu[2,R[1,2]]

Bu[2, R[1,2]] // βForm

(((2-3 (Subscript[T, 5])+2 (Subscript[T, 5]^2)-(Subscript[T, 5]^3)+(Subscript[T, 1]) (Subscript[T, 5]^3))/((Subscript[T, 5]^2) (1+(Subscript[T, 1])-(Subscript[T, 5])-2 (Subscript[T, 1]) (Subscript[T, 5])+2 (Subscript[T, 1]) (Subscript[T, 5]^2))))-1)*(((1+(Subscript[T, 1])-(Subscript[T, 5])-2 (Subscript[T, 1]) (Subscript[T, 5])+2 (Subscript[T, 1]) (Subscript[T, 5]^2))/((Subscript[T, 1]) (Subscript[T, 5]^3))))  // Simplify

βMVA[Bu[ω_,λ_,μ_]] := Module[
{lbls},
lbls = Rest[First /@ λ];
ω*Det[Outer[
Coefficient[μ-lbls.(lbls /. h[i_] :> t[i]), #1*#2]&,
lbls, lbls /. h[i_] :> t[i]
]]/(1-λ[[1,1]]/.h[i_]->(Subscript[T, i])) // Factor
];
βMVA[L_Link] := βMVA[Bu[h /@ (First /@ Skeleton[L]), βZ[L]]]

{βMVA[Bu[{h[1],h[5],h[9]},β0]], βMVA[L]}

{ω,λ,μ} = List @@ Bu[{h[1],h[5]},β0]

lbls = Rest[First /@ λ]

Factor[(MVA[#][T] /. T[i_] :> (Subscript[T, Skeleton[#][[i,1]]]))/βMVA[#]]&  /@ AllLinks[10]