Pensieve Header: Switching to the Burau presentation; continues pensieve://2012-02/.

βSimplify=Simplify;
SetAttributes[βCollect, Listable];
βCollect[B[ω_, μ_]] := B[
βSimplify[ω],
Collect[μ, _h, Collect[#, _t, βSimplify]&]
];
(* "L" for "Labels" *)
hL[β_] := Union[Cases[β, h[s_] :> s, Infinity]];
tL[β_] := Union[Cases[β, t[s_]|(Subscript[T, s_]) :> s, Infinity]];
dL[β_] := Union[hL[β], tL[β]];
βForm[B[ω_, μ_]] := Module[
{tails, heads, mat},
tails = tL[B[ω, μ]]; heads = hL[B[ω, μ]];
mat = Outer[βSimplify[Coefficient[μ, h[#1] t[#2]]]&, heads, tails];
PrependTo[mat, t /@ tails];
mat = Prepend[Transpose[mat], Prepend[h /@ heads, ω]];
MatrixForm[mat]
];
βForm[else_] := else /. {β_B :> βForm[β], β_Bu :> βForm[β]};

tm[x_, y_, z_][β_] := β /. {t[x]->t[z], t[y]->t[z], (Subscript[T, x])->(Subscript[T, z]), (Subscript[T, y])->(Subscript[T, z])};
hm[x_, y_, z_][B[ω_, μ_]] := Module[
{γx= D[μ, h[x]], γy=D[μ, h[y]], M=μ /. h[x]|h[y] -> 0},
B[ω, M+h[z](γx+γy+(γx /. t[i_] :> 1)γy)] // βCollect
];
thswap[y_,x_][B[ω_, μ_]] := Module[
{α, β, γ, δ, ϵ},
α = Coefficient[μ, h[x]t[y]];
β = D[μ, t[y]] /. h[x] -> 0;
γ = D[μ, h[x]] /. t[y] -> 0;
δ = μ /. h[x]|t[y] -> 0;
ϵ = 1+α;
B[ω*ϵ, Plus[
α(1+(γ /. t[i_] :> 1)/ϵ)h[x]t[y],
β(1+(γ /. t[i_] :> 1)/ϵ)t[y],
γ/ϵ h[x],
δ-1/ϵ γ*β
]] // βCollect
];
dm[x_,y_,z_][β_] := β // thswap[x,y] // hm[x,y,z] // tm[x,y,z];
B /: B[ω1_, μ1_]B[ω2_, μ2_] := B[ω1*ω2, μ1+μ2];
R[x_, y_] := B[1, ((Subscript[T, x])-1)*t[x]h[y]];
Ri[x_, y_] := B[1, (1/(Subscript[T, x])-1)*t[x]h[y]];

Unprotect[NonCommutativeMultiply];
β_ ** ν_ := Module[
{ρ, σ, labels},
ρ = β*(ν /. {h[s_] :> h[σ[s]], t[s_] :> t[σ[s]], (Subscript[T, s_]) :> (Subscript[T, σ[s]])});
labels = Union[Cases[{β,ν}, h[s_]|t[s_]|(Subscript[T, s_]) :> s, Infinity]];
Do[
ρ = ρ // dm[s, σ[s], s],
{s, labels}
];
ρ
];

βCollect[Bu[ω_, λ_, μ_]] := Bu[
βSimplify[ω],
Collect[λ, _h, βSimplify],
Collect[μ, _h, Collect[#, _t, βSimplify]&]
];
βForm[Bu[ω_, λ_, μ_]] := Module[
{tails, heads, mat},
tails = tL[B[ω, λ, μ]];
heads = hL[B[ω, λ, μ]];
mat = Outer[βSimplify[Coefficient[μ, h[#1] t[#2]]]&, heads, tails];
PrependTo[mat, t /@ tails];
mat = Prepend[Transpose[mat], Prepend[λ, ω]];
MatrixForm[mat]
];
Bu[n_Integer, β_B] := Bu[h /@ Range[n], β];
Bu[ηs_List, B[ω_, μ_]] :=  Module[{λ},
λ = (1+Coefficient[μ, #] /. t[i_] -> 1)& /@ ηs;
Bu[ω,
Thread[ηs -> λ],
-μ +(ηs /. h[j_] :> t[j]h[j]).λ
] // βCollect
];
B[Bu[ω_, λ_, μ_]] := βCollect[B[ω,
-μ+Total[λ /. (h[j_]->λj_) :> t[j]h[j]λj]
]];

{R[1,2],
R[1,2] // βForm,
Bu[2,R[1,2]],
Bu[2, R[1,2]] // βForm,
B[Bu[2,R[1,2]]],
B[Bu[2,R[1,2]]] // βForm
} // ColumnForm

n=3;
{
β1=B[1,Sum[(Subscript[α, 10i+j]) t[i]h[j], {i,n}, {j,n}]], Bu[n,β1],
β2=B[1, Sum[(Subscript[β, 10i+j]) t[i]h[j], {i,n}, {j,n}]], Bu[n,β2],
β1**β2,
Bu[n, β1**β2]
} // βForm // ColumnForm

n=3;
{
β1=Bu[ω1,Table[h[j]->(Subscript[λ1, j]), {j,n}],Sum[(Subscript[α1, 10i+j]) t[i]h[j], {i,n}, {j,n}]], B[β1],
β2=Bu[ω2,Table[h[j]->(Subscript[λ2, j]), {j,n}],Sum[(Subscript[α2, 10i+j]) t[i]h[j], {i,n}, {j,n}]], B[β2],
B[β1]**B[β2],
Bu[n, B[β1]**B[β2]]
} // βForm // ColumnForm

n=3;
{
β1=Bu[ω1,Table[h[j]->(Subscript[λ1, j]), {j,n}],
Sum[(Subscript[α1, 10i+j]) t[i]h[j]+(1/n-(Subscript[α1, 10i+j]))t[j]h[j], {i,n}, {j,n}]
], B[β1],
β2=Bu[ω2,Table[h[j]->(Subscript[λ2, j]), {j,n}],
Sum[(Subscript[α2, 10i+j]) t[i]h[j]+(1/n-(Subscript[α2, 10i+j]))t[j]h[j], {i,n}, {j,n}]
], B[β2],
B[β1]**B[β2],
Bu[n, B[β1]**B[β2]]
} // βForm // ColumnForm

n=3;
{
β1=Bu[ω,Table[h[j]->(Subscript[λ, j]), {j,n}],
Sum[(Subscript[α, 10i+j]) t[i]h[j]+(1/n-(Subscript[α, 10i+j]))t[j]h[j], {i,n}, {j,n}]
], B[β1],
B[β1] // dm[1,2,1],
Bu[n, B[β1] // dm[1,2,1]]
} // βForm // ColumnForm

n=4;
{
β1=Bu[ω,Table[h[j]->(Subscript[λ, j]), {j,n}],
Sum[(Subscript[α, 10i+j]) t[i]h[j]+(1/n-(Subscript[α, 10i+j]))t[j]h[j], {i,n}, {j,n}]
], B[β1],
B[β1] // dm[1,2,1],
Bu[n, B[β1] // dm[1,2,1]]
} // βForm // ColumnForm

n=5;
{
β1=Bu[ω,Table[h[j]->(Subscript[λ, j]), {j,n}],
Sum[(Subscript[α, 10i+j]) t[i]h[j]+(1/n-(Subscript[α, 10i+j]))t[j]h[j], {i,n}, {j,n}]
],
B[β1],
(Expand /@ Bu[n, B[β1] // dm[1,2,1]]) /. t[i_]h[i_] -> 0
} // βForm // ColumnForm