Pensieve Header: Programs to generate pictures of the Pachner moves.

{v1, v2, v3}= {Re[#], Im[#], 0}& /@ Table[E^(2Pi I k/3), {k,0,2}]

n={0,0,1};  s={0,0,-1};

P2={Simplex[n,v1,v2,v3], Simplex[s,v1, v2, v3]};
P3={Simplex[n,s,v2,v3], Simplex[n,s,v3,v1], Simplex[n,s,v1,v2]};

Draw3D[s_Simplex] := Table[
Polygon[List @@ Delete[s, k]],
{k,1,4}
];
Draw3D[l_List]  := Graphics3D[{
 Opacity[0.5],
Draw3D /@ l
}]

Draw3D[P3]

ShrinkTo[p_, s_Simplex] := Module[
{b=(1-p)Mean[List @@s]},
Expand[p#+b]& /@ s
];
ShrinkTo[p_, expr_] := expr /. s_Simplex :> ShrinkTo[p, s]

{
Draw3D[ShrinkTo[0.7, P2]],
Draw3D[ShrinkTo[0.6, P3]]
}