QuantumRoots package

A subpackage for QuantumGroups v2.
Version 2.0, June 11, 2005, Scott Morrison

Introduction

This package calculates the quantum roots for a quantum group.

Implementation

Start of package

Specify package dependencies:

BeginPackage["QuantumGroups`QuantumRoots`",{"QuantumGroups`","QuantumGroups`Utilities`Debugging`","QuantumGroups`MatrixPresentations`","QuantumGroups`Algebra`","QuantumGroups`RootSystems`","QuantumGroups`Representations`","QuantumGroups`BraidAction`","QuantumGroups`WeylGroups`"}];

Usage messages

ExpandQuantumRoot::usage="";

QuantumPositiveRoots::usage="";

QuantumNegativeRoots::usage="";

QuantumRootHeight::usage="";

Internals

Begin["`Private`"];

q=Global`q;

LoadQuantumRoots[(Subscript[Γ_, n_])]:=Module[{},
Off[Get::noopen,Needs::nocont];
Needs["QuantumGroups`Data`"<>SymbolName[Γ]<>ToString[n]<>"`QuantumRoots`"];
On[Get::noopen,Needs::nocont];
LoadQuantumRoots[(Subscript[Γ, n])]=False;
True
]

ExpandQuantumRoot[Γ_][SuperPlus[(Subscript[X, Γ_,r_])]]/;MemberQ[SimpleRoots[Γ],PositiveRoots[Γ][[r]]]:=SuperPlus[(Subscript[X, Position[SimpleRoots[Γ],PositiveRoots[Γ][[r]]][[1,1]]])]
ExpandQuantumRoot[Γ_][SuperPlus[(Subscript[X, Γ_,r_])]]:=ExpandQuantumRoot[Γ][SuperPlus[(Subscript[X, Γ,r])]]=
If[LoadQuantumRoots[Γ],ExpandQuantumRoot[Γ][SuperPlus[(Subscript[X, Γ,r])]],
With[{i=LongestWordDecomposition[Γ]},
DebugPrintHeld["Calculating ",ExpandQuantumRoot[Γ][SuperPlus[(Subscript[X, Γ,r])]]];
BraidAction[Γ][(Subscript[T, #])&/@Take[i,r-1],SuperPlus[(Subscript[X, i[[r]]])]]
]
]

ExpandQuantumRoot[Γ_][SuperMinus[(Subscript[X, Γ_,r_])]]:=ExpandQuantumRoot[Γ][SuperPlus[(Subscript[X, Γ,r])]]/.q->(q^(-1))/.{SuperPlus[(Subscript[X, i_])]:>SuperMinus[(Subscript[X, i])]}/.Z_NonCommutativeMultiply:>Reverse[Z]

Δ[A:(SuperPlus[(Subscript[X, Γ_,r_])]|SuperMinus[(Subscript[X, Γ_,r_])])]:=Δ[ExpandQuantumRoot[Γ][A]]

OperatorWeight[Γ_][SuperPlus[(Subscript[X, Γ_,r_])]]:=PositiveRoots[Γ][[r]]
OperatorWeight[Γ_][SuperMinus[(Subscript[X, Γ_,r_])]]:=-PositiveRoots[Γ][[r]]

QuantumPositiveRoots[Γ_]:=Table[SuperPlus[(Subscript[X, Γ,i])],{i,1,Length[LongestWordDecomposition[Γ]]}]
QuantumNegativeRoots[Γ_]:=Table[SuperMinus[(Subscript[X, Γ,i])],{i,1,Length[LongestWordDecomposition[Γ]]}]

MatrixPresentation[Γ_][A:(SuperPlus[(Subscript[X, Γ_,r_])]|SuperMinus[(Subscript[X, Γ_,r_])])][V_,β_,λ_]:=MatrixPresentation[Γ][A][V,β,λ]=MatrixPresentation[Γ][ExpandQuantumRoot[Γ][A]][V,β,λ]

QuantumRootHeight[Γ_][SuperPlus[(Subscript[X, Γ_,r_])]|SuperMinus[(Subscript[X, Γ_,r_])]]:=Plus@@(PositiveRoots[Γ][[r]].Inverse[SimpleRoots[Γ]])

End[];

End of package

EndPackage[];