Pensieve header: Invariance proof by Roland.

Proof of invariance under Reidemeister 3

The program to compute the ρ invariant.

ρ[K_]:=ρ[K]=Module[{Cs,r,n,B,A,c,s,i,j,Δ,G,g,ρ1},
{Cs,r}=List@@RVK[K]; n=Length[Cs]; B=Table[0,2n,2n+1];
Do[{s,i,j}=c;B[[{i,j},{i,j,i+1,j+1}]]=(({{1, 0, -1, 0}, {0, 1, (T^s)-1, -(T^s)}})),{c,Cs}];
A=B[[All,2;;]];
Δ=(T^((Total[r]-Total[First/@Cs])/2))Det[A];
G=Prepend[Table[0,2n]][Inverse[A]]; (Subscript[g, α_,β_]):=G[[α,β]];
ρ1=(Δ^2)Sum[{s,i,j}=c;s((1-(T^s))(Subscript[g, i,j])((Subscript[g, i,j])-(Subscript[g, j,j]))+2(Subscript[g, i,i])(Subscript[g, i,j])-(Subscript[g, i,j])(Subscript[g, j,i])-(Subscript[g, i,i])(Subscript[g, j,j])-(Subscript[g, i,j])+(Subscript[g, j,j])-1/2),{c,Cs}];
ρ1+=(Δ^2)Sum[r[[k]]((Subscript[g, k,k])-1/2),{k,2n}] ;
Factor@{Δ,ρ1}];

(Subscript[δ, i_,j_]):=If[Simplify[i]===Simplify[j],1,0] (*Kronecker delta*)

We start by deriving four relations on the matrix entries of G. These should be derivable directly from (A^(-1))A = I using the fact that we know B explicitly.
I however derived them from the Heisenberg commutation relations. In these equations {i,j} stands for the overpass and underpass at the same crossing, α can be arbitrary.

(Subscript[rule1i, α_,i_,j_]):=(Subscript[g, i+1,α])->(Subscript[g, i,α])-(Subscript[δ, i,α])
(Subscript[rule1j, α_,i_,j_]):=(Subscript[g, j+1,α])->(Subscript[g, j,α])-(Subscript[δ, j,α])+(1-(T^(-1)))((Subscript[g, i,α])-(Subscript[δ, i,α])-(Subscript[g, j,α])+(Subscript[δ, j,α]))
(Subscript[rule2i, α_,i_,j_]):=(Subscript[g, α,i+1])->(Subscript[g, α,i])+(1-T)(Subscript[g, α,j])+(Subscript[δ, α,i+1])
(Subscript[rule2j, α_,i_,j_]):=(Subscript[g, α,j+1])->T (Subscript[g, α,j])+(Subscript[δ, α,j+1])

We encode the edges near the Reidemeister 3 move as shown:

(Canvas[(CanvasFrame)])

The crossings in the left hand side are listed in LXs and those of the righthand picture are in RXs. The format of a crossing is to list the overpass first. All crossings are positive.

LXs = {{a,c+1},{b,c},{a+1,b+1}};
RXs = {{a,b},{a+1,c},{b+1,c+1}};

Next use the above relations to generate rewriting rules expressing (Subscript[g, x,y]) in terms of (Subscript[g, a|b|c , a|b|c])

LRules=Flatten@Table[{i,j}=cr;{(Subscript[rule1i, k,i,j]),(Subscript[rule1j, k,i,j]),(Subscript[rule2i, k,i,j]),(Subscript[rule2j, k,i,j])}
,{cr,LXs},{k,{a,b,c,a+1,b+1,c+1}}];
RRules=Flatten@Table[{i,j}=cr;{(Subscript[rule1i, k,i,j]),(Subscript[rule1j, k,i,j]),(Subscript[rule2i, k,i,j]),(Subscript[rule2j, k,i,j])}
,{cr,RXs},{k,{a,b,c,a+1,b+1,c+1}}];

According to the above program the weight assigned to each crossing  {i,j} is given as below.

(Subscript[CrossingWeight, i_,j_]):=(1-T)(Subscript[g, i,j])((Subscript[g, i,j])-(Subscript[g, j,j]))+2(Subscript[g, i,i])(Subscript[g, i,j])-(Subscript[g, i,j])(Subscript[g, j,i])-(Subscript[g, i,i])(Subscript[g, j,j])-(Subscript[g, i,j])+(Subscript[g, j,j])-1/2

Assuming that the matrix entries (Subscript[g, x,y]) from the LHS and the RHS are equal when neither of x,y are in {a+1,b+1,c+1} 
we can thus proceed to check invariance under Reidemeister 3 directly as below.

R3LHS=Sum[{i,j}=cr;(Subscript[CrossingWeight, i,j]),{cr,LXs}]
R3RHS=Sum[{i,j}=cr;(Subscript[CrossingWeight, i,j]),{cr,RXs}]

(R3LHS//.LRules)-(R3RHS//.RRules)//Simplify